Question

这与我最近关于Fortran流等的文章有点相关：Converting data stored in Fortran 90 binaries to human readable format。

我试图将一个简单的整数数组写入文件，然后使用Fortran的READ函数然后读入我创建的二进制文件。我通过在ACCESS="STREAM"指令中包含OPEN来使用流。我有以下代码：

MODULE streamtest2subs

  IMPLICIT NONE

CONTAINS

SUBROUTINE writeUstream(myarray)
  IMPLICIT NONE
  INTEGER, INTENT(IN), DIMENSION(4,10) :: myarray
  INTEGER :: myvalue = 12345, mypos
  OPEN(UNIT=11, FILE="ustream.demo", STATUS="REPLACE", ACCESS="STREAM")
  WRITE(11) myarray
  CLOSE(UNIT=11)
END SUBROUTINE writeUstream

SUBROUTINE readUstream
  IMPLICIT NONE
  INTEGER :: test1, test2, test3
  INTEGER :: n
  OPEN(UNIT=42, FILE="ustream.demo", STATUS="OLD", ACCESS="STREAM")
  READ(42, POS=1) test1
  READ(42, POS=2) test2
  READ(42, POS=3) test3

  WRITE(*,*) "This is the output:"
  WRITE(*,*) test1
  WRITE(*,*) test2
  WRITE(*,*) test3
END SUBROUTINE readUstream

END MODULE streamtest2subs

PROGRAM streamtest2
  USE streamtest2subs
  IMPLICIT NONE
  INTEGER :: i, j, k
  INTEGER, DIMENSION(4,10) :: a

  WRITE(*,*) "This is my input array:"
  k=1
  DO i=1,4
    DO j=1,10
      a(i,j)=k
      WRITE(*, "(i3)", ADVANCE="NO") a(i,j)
      k=k+1
    END DO
    WRITE(*,*)
  END DO
  WRITE(*,*)

  CALL writeUstream(a)
  CALL readUstream
END PROGRAM streamtest2

但是，当我使用gfortran编译它并运行它时，我得到以下输出：

 This is my input array:
  1  2  3  4  5  6  7  8  9 10
 11 12 13 14 15 16 17 18 19 20
 21 22 23 24 25 26 27 28 29 30
 31 32 33 34 35 36 37 38 39 40

 This is the output:
           1
   184549376
      720896

为什么输出如此复杂？是READ是将 ustream.demo 文件作为字符串而不是整数读取吗？但是，当我将test1，test2和test3的类型更改为string时，我的输出只是一系列三个空行。

我是否错误地使用了POS中的READ指令？我认为POS指定输出中的字符编号（虽然我不确定数组的元素是否以任何方式分隔）;这是对的吗？

非常感谢你的时间！

Answer 1

出于您在上一个问题中描述的目的，我认为您编程的过程比必要的更复杂。假设您需要没有额外记录结构的二进制文件，则需要未格式化和流式传输。您可以像编写文件一样阅读文件 - 您不需要使用POS - 除非目的是学习如何使用POS。

我测试的示例基于Fortran程序，在其中我读取了由其他人编写的二进制文件，几乎可以肯定是使用C程序编写的。该文件由标题组成，后跟可变长度的数组。我打开文件：

open ( unit=75, file=FileName, status='old', access='stream', form='unformatted', action='read' )

我读了一个标题（一个带有许多子变量的用户定义类型的变量）：

read (75) header

我将数组分配到读入标题的一个字段的长度，然后我读取数组：

allocate ( array (1:header % ArrayLen) )
read (75) array

然后我处理数组中的数据。然后我重复直到文件结束（代码示例中没有显示）。

非常简单......无需计算文件中的位置并使用READ的POS关键字。

Answer 2

问题是你的read语句，POS是从文件开头的字节偏移量，并且与写入文件的原始a数组的数组索引没有直接关系

因此，在您的代码中，如果test1是4字节整数，Fortran读取将通过读取文件的字节1到4来构造它。类似地，test2将从字节2到5构造，而该值实际上存储在字节5到8中。

当我将读取行更改为

时

READ(42, POS=1) test1
READ(42, POS=5) test2
READ(42, POS=9) test3

输出变为，

This is my input array:
1  2  3  4  5  6  7  8  9 10
11 12 13 14 15 16 17 18 19 20
21 22 23 24 25 26 27 28 29 30
31 32 33 34 35 36 37 38 39 40

This is the output:
       1
      11
      21

我认为这更像是你追求的。请注意，如果值最初写入文件，例如2字节或8字节整数，那么在读取文件时，您必须考虑POS偏移中的那些大小。

顺便说一下，学习命令行工具od以便快速查询二进制文件是值得的。例如，我做的第一件事是使用

检查写入工作正常

$ od -t d4 ustream.demo 
0000000                 1              11              21              31
0000020                 2              12              22              32
0000040                 3              13              23              33
0000060                 4              14              24              34
0000100                 5              15              25              35
0000120                 6              16              26              36
0000140                 7              17              27              37
0000160                 8              18              28              38
0000200                 9              19              29              39
0000220                10              20              30              40
0000240

正确使用Fortran流来编写和读取整数数组

2 个答案: