Question

我在emacs中使用openwith包。我想用xfig打开带有一些附加选项的.fig文件，例如：

xfig -specialtext -latexfont -startlatexFont default file.fig

openwith正在为我提供其他文件关联，我不需要传递其他选项。我在.emacs文件中尝试了以下内容

(setq
 openwith-associations 
 '(("\\.fig\\'" "xfig" (file))))

有效，但

(setq
 openwith-associations 
 '(("\\.fig\\'" "xfig -specialtext -latexfont -startlatexFont default" (file))))

不起作用(error: Wrong type argument: arrayp, nil)，也

(setq
 openwith-associations 
 '(("\\.fig\\'" "xfig" (" -specialtext -latexfont -startlatexFont default " file))))

不起作用，虽然在这里我没有得到任何错误。它说“在外部程序中打开file.fig”但没有任何反应。在这种情况下，我注意到有一个运行所有这些选项的xfig进程。

有人能让我知道如何解决这个问题吗？

感谢您的帮助。

Answer 1

我不知道这是如何工作的，所以我只记录了如何通过阅读代码来解决这个问题：

openwith.el中的重要代码是调用start-process：

(dolist (oa openwith-associations)
  (let (match)
    (save-match-data
      (setq match (string-match (car oa) (car args))))
    (when match
      (let ((params (mapcar (lambda (x)
                  (if (eq x 'file)
                  (car args)
                  (format "%s" x))) (nth 2 oa))))
    (apply #'start-process "openwith-process" nil
           (cadr oa) params))
      (kill-buffer nil)
      (throw 'openwith-done t))))

在你的情况下oa将具有以下结构，并且cadr是“xfig”：

(cadr '("\.fig\'" "xfig" (file))) ;; expands to => xfig

这是启动过程的定义和文档：

功能： start-process 名称缓冲区或名称程序＆amp; rest args http://www.gnu.org/software/emacs/elisp/html_node/Asynchronous-Processes.html

 args, are strings that specify command line arguments for the program.

一个例子：

(start-process "my-process" "foo" "ls" "-l" "/user/lewis/bin")

现在我们需要弄清楚如何构造params。在您的示例中，mapcar的参数是：

(nth 2 '("\.fig\'" "xfig" (file))) ;=> (file)

顺便说一句，您可以在emacs的 scratch 缓冲区中编写这些行，并使用C-M-x运行它们。

（car args）指的是你给openwith-association的参数，注意'file in（nth 2 oa）的出现是如何被替换的。我现在就用“here.txt”替换它：

(mapcar (lambda (x)
      (if (eq x 'file)
          "here.txt"
          (format "%s" x))) (nth 2 '("\.fig\'" "xfig" (file)))) ;=> ("here.txt")

好的，现在我们看看应该如何构建参数：

(mapcar (lambda (x)
      (if (eq x 'file)
          "here.txt"
          (format "%s" x))) 
    (nth 2 '("\.fig\'" "xfig" 
         ("-specialtext" "-latexfont" "-startlatexFont" "default" file))))
; => ("-specialtext" "-latexfont" "-startlatexFont" "default" "here.txt")

试试这个：

(setq openwith-associations 
 '(("\\.fig\\'" "xfig" ("-specialtext" "-latexfont" "-startlatexFont" "default" file))))

您必须在参数列表中将每个单词作为单个字符串提供。

emacs / openwith如何将参数传递给程序？

1 个答案: