Question

我希望在我的XML文档上做一些非常简单的XSLT，它的结构如下：

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT />
        <TAG2 attribute2="B" attribute3="34" />
    </TAG1>
</XML>

我正在尝试制作一个执行以下操作的XSLT：

复制所有内容
如果TAG2 @ attribute1 =“A”AND TAG2 @ attribute2 =“B”并且没有TAG2 @ attribute4，则将@ attribute4添加到TAG2并使其值为TAG2 @ attribute3

我的失败尝试如下。我得到的错误是 “xsl：attribute：如果已将子元素添加到元素中，则无法向元素添加属性。”

谢谢！

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"  
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:param name="newDocumentHeader" />

   <!-- copy idiom copying ALL nodes -->
   <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node() | @*" />
      </xsl:copy>
   </xsl:template>

   <!-- override for special case -->
   <xsl:template match="TAG1[@attribute1='A']/TAG2[@attribute2='B'][not(@attribute4)]">
        <xsl:attribute name="attribute4">
        <xsl:value-of select="@attribute3" />
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

Answer 1

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="TAG1[@attribute1 = 'A']/TAG2[@attribute2= 'B' ][not(@attribute4)]">
        <xsl:copy>
            <xsl:attribute name="attribute4">
                <xsl:value-of select="@attribute3" />
            </xsl:attribute>
            <xsl:apply-templates  select="node() | @*"/>
        </xsl:copy>

    </xsl:template>

</xsl:stylesheet>

结果：

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT />
        <TAG2 attribute4="34" attribute2="B" attribute3="34" />
    </TAG1>
</XML>

Answer 2

XSLT代码中缺少的只是匹配元素的副本。但是，在您的情况下（ 简单XSLT属性添加 ），您可以直接覆盖attribute3节点：

<xsl:template match="TAG1[@attribute1='A']
         /TAG2[@attribute2='B' and not(@attribute4)]
          /@attribute3">
    <xsl:copy-of select="."/>
    <xsl:attribute name="attribute4">
        <xsl:value-of select="." />
    </xsl:attribute>
</xsl:template>

集成在您当前的转换中，生成：

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT></IRRELEVANT>
        <TAG2 attribute2="B" attribute3="34" attribute4="34"></TAG2>
    </TAG1>
</XML>

简单的XSLT属性添加

2 个答案: