Question

我是一名XSLT新手，有一个简单的任务：

假设我有以下XML：

<Element1>
    <Element2 attr1="1"/>
</Element1>
<Element1 attr1="2"/>
<Element1>
    <Element2 attr1="2"/>
</Element1>

我希望通过一次更改将XML转换为相同的XML：所有名为“attr1”的属性，无论它们在哪里都必须进行转换，例如“1”将是“A”，“2”将是“X”，我。即到

<Element1>
    <Element2 attr1="A"/>
</Element1>
<Element1 attr1="X"/>
<Element1>
    <Element2 attr1="X"/>
</Element1>

我怎样才能做到这一点？提前谢谢！

Answer 1

您可以定义要替换和替换字符的字符，然后使用translate。您可以使用此XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:variable name="in">12</xsl:variable>
    <xsl:variable name="out">AX</xsl:variable>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:attribute name="attr1">
            <xsl:value-of select="translate(., $in, $out)"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

另一种方式：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:choose>
            <xsl:when test=". = '1'">
                <xsl:attribute name="attr1">
                    <xsl:text>A</xsl:text>
                </xsl:attribute>
            </xsl:when>
            <xsl:when test=". = '2'">
                <xsl:attribute name="attr1">
                    <xsl:text>X</xsl:text>
                </xsl:attribute>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

<xsl:template match="@attr1">将匹配所有属性attr1，然后使用xsl:choose为此属性创建适当的值。

Answer 2

你没有说当@ attr = 3时会发生什么，所以如果它不是被选中的那个，那么只有复制值的else子句。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="@attr1">
  <xsl:attribute name="attr1">
    <xsl:choose>
      <xsl:when test=". = 1">
        <xsl:text>A</xsl:text>
      </xsl:when>
      <xsl:when test=". = 2">
        <xsl:text>X</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="." />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:attribute>
</xsl:template>
</xsl:stylesheet>

Answer 3

另一种方法，使用document函数：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:l="local"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:attribute name="attr1">
            <xsl:value-of select="document('')//l:item[l:in = current()]/l:out"/>
        </xsl:attribute>
    </xsl:template>

    <xml xmlns="local">
        <item>
            <in>1</in>
            <out>A</out>
        </item>
        <item>
            <in>2</in>
            <out>X</out>
        </item>
    </xml>

</xsl:stylesheet>

Answer 4

下面的xslt 2版本有效：

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1[.='1']">
        <xsl:attribute name="attr1">
            <xsl:value-of select="replace(.,'1','A')"/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="@attr1[.='2']">
        <xsl:attribute name="attr1">
            <xsl:value-of select="replace(.,'2','X')"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

XSLT：更改某些属性值

4 个答案: