Question

请问，是否有人知道如何用汇编语言编写字符串输入？我正在使用int 21来显示和输入字符。

Answer 1

您可以使用function 0Ah来读取缓冲输入。给定ds:dx中的字符串缓冲区，它读取长度为255的字符串。缓冲区布局为：

Byte 0 String length (0-255)
Byte 1 Bytes read (0-255, filled by DOS on return)
Bytes 2-..Length+2 (The character string including newline as read by DOS).

一个小型COM文件的示例，该文件读取字符串然后将其回送给用户：

    org 0x100

start:
    push cs
    pop ds ; COM file, ds = cs

    mov ah, 0x0A ; Function 0Ah Buffered input
    mov dx, string_buf ; ds:dx points to string buffer
    int 0x21

    movzx si, byte [string_buf+1] ; get number of chars read

    mov dx, string_buf + 2 ; start of actual string

    add si, dx ; si points to string + number of chars read
    mov byte [si], '$' ; Terminate string

    mov ah, 0x09 ; Function 09h Print character string
    int 0x21 ; ds:dx points to string

    ; Exit
    mov ax, 0x4c00
    int 0x21

string_buf: 
    db 255 ; size of buffer in characters
    db 0 ; filled by DOS with actual size
    times 255 db 0 ; actual string

请注意，它会覆盖输入行（因此可能看起来程序没有做任何事情！）

或者你可以使用function 01h并在循环中自己阅读这些字符。这样的事情（注意如果输入超过255个字符，它将溢出以后的缓冲区）：

    org 0x100

start:
    push cs
    pop ax
    mov ds, ax
    mov es, ax; make sure ds = es = cs

    mov di, string ; es:di points to string
    cld ; clear direction flag (so stosb incremements rather than decrements)
read_loop:
    mov ah, 0x01 ; Function 01h Read character from stdin with echo
    int 0x21
    cmp al, 0x0D ; character is carriage return?
    je read_done ; yes? exit the loop
    stosb ; store the character at es:di and increment di
    jmp read_loop ; loop again
read_done:
    mov al, '$'
    stosb ; 'Make sure the string is '$' terminated

    mov dx, string ; ds:dx points to string
    mov ah, 0x09 ; Function 09h Print character string
    int 0x21

    ; Exit
    mov ax, 0x4c00
    int 0x21

string: 
    times 255 db 0 ; reserve room for 255 characters

Answer 2

字符串只是一系列字符，因此您可以在循环内部使用int 21代码来获取字符串，一次一个字符。在数据段中创建一个标签来保存您的字符串，每次读取一个字符时，将其复制到该标签（每次递增一个偏移量，以便按顺序存储字符）。读取某个字符时停止循环（可能输入）。

手动完成所有这些操作非常繁琐（想想退格将如何工作）但你可以做到。或者，您可以链接stdio，stdlib等，并调用库函数为您完成大部分工作。

如何用汇编语言输入字符串？

2 个答案: