Question

我想从groovy编写的函数中返回多个值并接收它们，但是我收到错误

class org.codehaus.groovy.ast.expr.ListExpression，其值为[a， b]'，作为作业的左手边是一个坏表达操作

我的代码是

int a=10
int b=0
println "a is ${a} , b is ${b}"
[a,b]=f1(a)
println "a is NOW ${a} , b is NOW ${b}"

def f1(int x) {   
  return [a*10,a*20]
}

Answer 1

你几乎拥有它。从概念上讲，[ a, b ]会创建一个列表，并( a, b )展开一个列表，因此您需要(a,b)=f1(a)而不是[a,b]=f1(a)。

int a=10
int b=0
println "a is ${a} , b is ${b}"
(a,b)=f1(a)
println "a is NOW ${a} , b is NOW ${b}"

def f1(int x) {
    return [x*10,x*20]
}

返回对象的另一个示例，不需要是相同的类型：

final Date foo
final String bar
(foo, bar) = baz()
println foo
println bar

def baz() {
    return [ new Date(0), 'Test' ]
}

此外，您可以组合声明和作业：

final def (Date foo, String bar) = baz()
println foo
println bar

def baz() {
    return [ new Date(0), 'Test' ]
}

Answer 2

您可以声明并将返回值存储在一行中的变量分配给这样一行，这是一种比Justin的答案中使用的语法更紧凑的语法：

def (int a, int b) = f1(22)

在您的特定情况下，您可能无法使用此功能，因为传递给f1的其中一个变量也用于存储返回值

Answer 3

在Jenkins管道作业的上下文中运行Groovy时，上述答案不起作用（至少在版本2.60.2上），但以下是：

node {
    obj = ret2()
    fw = obj[0]
    lw = obj[1]
    echo "fw=${fw}"
    echo "lw=${lw}"
}

def ret2()
{
    return [5, 7]
}

或者：

node {
    obj = ret2()
    fw = obj.a
    lw = obj.b
    echo "fw=${fw}"
    echo "lw=${lw}"
}

def ret2()
{
    return [a:5, b:7]
}