Question

我是flash和actionscript的新手。

我希望在生成后修改flash的xml文件。

您可以看到本教程 http://www.webwasp.co.uk/tutorials/A_IntAct-02-drag-drop/index.php 这里当我改变位置时我想要更新新的xml文件。

任何帮助都非常适合。谢谢，

Answer 1

我几乎不知道你的要求是什么，我创建了一个可以拖放的正方形的例子。当它被删除时，它会将xml写入xml文件，其中包含丢弃的正方形的x和y坐标：

package 
{
    import flash.display.*;
    import flash.events.*;
    import flash.filesystem.*;
    import flash.utils.*;

    public class Main extends Sprite 
    {
        private var _square:Square;

        public function Main():void 
        {
            _square = new Square();
            _square.addEventListener(MouseEvent.MOUSE_DOWN, onSquareMouseDown);
            addChild(_square);

        }// end function

        private function onSquareMouseDown(e:Event):void
        {
            _square.startDrag();

            stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);

        }// end function

        private function onStageMouseUp(e:Event):void
        {
            stage.removeEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
            _square.stopDrag();

            var xml:XML = <dragAndDrop>
                              <x>{_square.x}</x>
                              <y>{_square.y}</y>
                          </dragAndDrop>;

            var file:File = File.desktopDirectory.resolvePath("xml/dragAndDrop.xml");
            var fileStream:FileStream = new FileStream();
            fileStream.open(file, FileMode.WRITE);
            fileStream.writeMultiByte(String(xml), "iso-8859-01");
            fileStream.close();

        }// end function

    }// end class

}// end package

import flash.display.Sprite;

internal class Square extends Sprite
{
    public function Square()
    {
        graphics.beginFill(0xFF0000);
        graphics.drawRect(0, 0, 100, 100);
        graphics.endFill();

    }// end function

}// end class

Answer 2

网站上提供的示例是指mx 2004.您可以看到更新的example here。

修改flash生成的xml？

2 个答案: