如何在单击按钮时动态地将组件添加到TScrollBox？

Question

我创建了一个TScrollBox。我在Button按钮上动态添加了Label和Edit Box。为了设置组件的位置，我使用了组件的高度，宽度，左侧，顶部属性。 但是当Scroll Bar在添加了5个组件后出现在屏幕上时，下一个组件位置会受到干扰。并且下一个组件不会以同步方式放在ScrollBox上。

Answer 1

放置在ScrollBox上的控件的Top坐标需要考虑已经发生的“滚动”量。如果你一次性添加控件，这不是问题，因为ScrollBox没有机会“滚动”。

如果在之后向ScrollBox 添加控件，它有机会“滚动”，则需要考虑发生的垂直“滚动”量。这是一段代码示例，它会向ScrollBox1添加标签，将垂直滚动考虑在内，因此控件不会相互重叠。在这里，我使用表单的“标记”属性来保存Top以添加下一个控件，我还使用Tag为标签生成唯一的名称（这样你就可以看到它们'在正确的坐标处进入ScrollBox。）

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Tag + ScrollBox1.VertScrollBar.Size - ScrollBox1.VertScrollBar.Position;
  Tag := Tag + L.Height;
end;

我有时使用的另一种方法是跟踪最后添加的控件，并将新控件的坐标基于最后添加的控件的坐标：

var LastControl: TControl;

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  if Assigned(LastControl) then
    L.Top := LastControl.Top + LastControl.Height
  else
    L.Top := 0;
  Tag := Tag + L.Height;

  LastControl := L;
end;

然而另一种方法是找到最低控件并根据它的坐标添加控件：

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
    Bottom, TestBottom: Integer;
    i: Integer;
begin
  // Find "Bottom"
  Bottom := 0;
  for i:=0 to ScrollBox1.ControlCount-1 do
    with ScrollBox1.Controls[i] do
    begin
      TestBottom := Top + Height;
      if TestBottom > Bottom then
        Bottom := TestBottom;
    end;
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Bottom;
  Tag := Tag + L.Height;
end;