我有一个 oracle 触发器可以将数据插入到另一个表中。如果我使用单个更新查询,那么它会起作用,但是如果我使用多个命令(例如更新和插入),它会因错误跟随错误而失败。
ORA-04091: table ADMIN_SMS_HANDLER is mutating, trigger/function may not see it
ORA-06512: at "ADMIN_SMS_TRIG", line 16
ORA-04088: error during execution of trigger 'ADMIN_SMS_TRIG'
这行得通。
CREATE OR REPLACE TRIGGER ADMIN_SMS_TRIG AFTER
INSERT ON ADMIN_SMS_HANDLER
FOR EACH ROW
DECLARE BEGIN
INSERT INTO SMS (
SMSID,
ANUMBER,
BNUMBER,
MSG,
APP
) VALUES (
SMSSEQ.NEXTVAL,
:NEW.SMS_FROM,
:NEW.SMS_TO,
:NEW.SMS_TEXT,
'APP'
);
END;
但这不起作用
CREATE OR REPLACE TRIGGER ADMIN_SMS_TRIG AFTER
INSERT ON ADMIN_SMS_HANDLER
FOR EACH ROW
DECLARE BEGIN
INSERT INTO SMS (
SMSID,
ANUMBER,
BNUMBER,
MSG,
APP
) VALUES (
SMSSEQ.NEXTVAL,
:NEW.SMS_FROM,
:NEW.SMS_TO,
:NEW.SMS_TEXT,
'app'
);
UPDATE ADMIN_SMS_HANDLER
SET
SENT_DATE = SYSDATE,
SENT_STATUS = 1,
UPDATED_BY = 'trigger',
UPDATED_DATE = SYSDATE
WHERE
ID = :NEW.ID;
END;
答案 0 :(得分:2)
该问题与多个语句无关。问题是行级触发器(通常)无法引用定义它的表。
假设目的是让触发器自动填充某些列,您可以通过直接在 :new
伪记录中设置值来实现,即
:new.sent_date := sysdate;
:new.sent_status := 1;
但由于您想修改当前行中的数据,您需要使用 before insert
触发器而不是 after insert
触发器。类似的东西
CREATE OR REPLACE TRIGGER ADMIN_SMS_TRIG
BEFORE INSERT ON ADMIN_SMS_HANDLER
FOR EACH ROW
DECLARE
BEGIN
INSERT INTO SMS (
SMSID,
ANUMBER,
BNUMBER,
MSG,
APP
) VALUES (
SMSSEQ.NEXTVAL,
:NEW.SMS_FROM,
:NEW.SMS_TO,
:NEW.SMS_TEXT,
'app'
);
:new.SENT_DATE := SYSDATE;
:new.SENT_STATUS := 1;
:new.UPDATED_BY := 'trigger';
:new.UPDATED_DATE := SYSDATE;
END;