Question

我正在SAP中创建一个简单的ALV网格。到目前为止，我已经能够用我的数据填充网格，并在选择屏幕后显示网格没问题。我没有将网格添加到自定义屏幕上的自定义容器中。只需查看网格全屏。

我的问题是 - 我是否需要设置alv网格对象的属性才能查看通常位于网格顶部的工具栏，其中包含用于过滤，排序等的按钮？

到目前为止，这就是我所拥有的：

TRY.
  cl_salv_table=>factory(
    IMPORTING
      r_salv_table   = gr_alv
    CHANGING
      t_table        = tbl_data
      ).
CATCH cx_salv_msg.
ENDTRY.

* initialize the alv settings - nothing done here for the moment.
PERFORM define_settings USING gr_alv.

* Display the ALV
gr_alv->display( ).

对SAP noob的任何帮助都将不胜感激。

Answer 1

每个ALV函数在Simple ALV中作为单独的CLASS实现，因此您必须单独处理它们。您不需要自定义控件。

要添加工具栏：

data: lr_func TYPE REF TO CL_SALV_FUNCTIONS_LIST.
"Functions
lr_func = gr_alv->get_functions( ).
lr_func->set_all( ).

完成ALV显示：

form display_results.

  data: ls_key        type salv_s_layout_key,

        lo_table      type ref to cl_salv_table,
        lo_cols       type ref to cl_salv_columns_table,
        lo_events     type ref to cl_salv_events_table,
        lo_funcs      type ref to cl_salv_functions_list,
        lo_layout     type ref to cl_salv_layout,
        lo_display    type ref to cl_salv_display_settings,
        lo_selections type ref to cl_salv_selections.

  try.
      call method cl_salv_table=>factory
        exporting
          list_display = abap_false
        importing
          r_salv_table = lo_table
        changing
          t_table      = gt_list.
    catch cx_salv_msg .                                 "#EC NO_HANDLER
  endtry.
  "Events
  create object go_events.
  lo_events = lo_table->get_event( ).
  set handler go_events->double_click for lo_events.

  "Layouts
  ls_key-report = sy-repid.
  lo_layout = lo_table->get_layout( ).
  lo_layout->set_key( ls_key ).
  lo_layout->set_default( abap_true ).
  lo_layout->set_save_restriction( ).
  lo_layout->set_initial_layout( p_var ).

  lo_cols = lo_table->get_columns( ).
  perform change_columns changing lo_cols.

  "Functions
  lo_funcs = lo_table->get_functions( ).
  lo_funcs->set_all( ).

  "Display Settings
  lo_display = lo_table->get_display_settings( ).
  lo_display->set_striped_pattern( abap_true ).

  "Selections
  lo_selections = lo_table->get_selections( ).
  lo_selections->set_selection_mode( if_salv_c_selection_mode=>row_column ).

  lo_table->display( ).
endform.                   " DISPLAY_RESULTS

Answer 2

看来你需要做的是从你的网格对象中获取一个CL_SALV_FUNCTIONS_LIST实例，如下所示：

data: lr_func TYPE REF TO CL_SALV_FUNCTIONS_LIST.
lr_func = gr_alv->get_functions( ).
lr_func->set_all( ).

但是，从那里，你似乎需要做一些或工作。我的建议：查看类CL_SALV_TABLE和CL_SALV_FUNCTIONS_LIST的文档（即，在事务SE24中显示类时单击文档按钮）。后者告诉你你到底需要做什么。

（另外，一点提示：将处理逻辑放在try-catch块中，因为如果初始化失败，你可能会捕获该异常，但继续尝试在未实例化或未初始化的类上调用方法）。

Answer 3

当您使用ALV对象模型时，这首先令人困惑。如果在全屏模式下使用ALV，则必须在程序中引用GUI状态，并在网格实例上使用方法SET_SCREEN_STATUS。它在SAP帮助here中进行了解释。

有助于将GUI状态SALV_TABLE_STANDARD从功能组SALV_METADATA_STATUS复制到报告中作为起点，然后您可以删除任何不需要的功能。例如，如果您将状态作为ALV_STATUS复制到程序中，则应写入：

gr_alv->set_screen_status( report   = sy-repid
                           pfstatus = 'ALV_STATUS' ).

如果要使用基于类的设置ALV函数的模型，则必须将网格对象嵌入到屏幕中的自定义容器中。

Answer 4

向您的gui添加客户容器
创建类cl_gui_custom_container的对象并提供容器的名称
创建类cl_gui_alv_grid的实例并提供自定义容器对象
使用方法set_table_for_first_display

这将显示包含所有按钮的工具栏。您可以使用IT_TOOLBAR_EXCLUDING参数控制工具栏中所需的按钮到set_table_for_first_display方法。

ALV网格缺少工具栏

4 个答案: