Question

使用 eksctl cli 可以创建 Fargate 类型的 EKS 集群，该集群创建实例类型为“Fargate”的节点。

如何使用 terraform 实现相同的目标？集群可以用节点组创建，但是实例类型 Fargate 好像不存在（虽然 eksctl 是这样创建的）

  node_groups = {
    eks_nodes = {
      desired_capacity = 3
      max_capacity     = 3
      min_capaicty     = 3

      instance_type = "Fargate"
    }
  }

谢谢！

Answer 1

您是否尝试过先定义 Fargate profile？

您必须至少定义一个 Fargate 配置文件，指定哪些 Pod 在启动时应使用 Fargate。您还需要创建一个 pod execution role，这样 Fargate 基础设施上运行的组件需要代表您调用 AWS API 以执行诸如从 Amazon ECR 提取容器映像或将日志路由到其他 AWS 服务等操作。

aws eks fargage 的 terraform 代码如下所示：

resource "aws_eks_fargate_profile" "default" {
  cluster_name           = var.cluster_name
  fargate_profile_name   = var.fargate_profile_name
  pod_execution_role_arn = join("", aws_iam_role.default.arn)
  subnet_ids             = var.subnet_ids
  tags                   = var.tags

  selector {
    namespace = var.kubernetes_namespace
    labels    = var.kubernetes_labels
  }
}

确保您使用 aws_eks_fargate_profile 资源创建 eks fargate 配置文件。

fargate pod 执行角色的 terraform 代码如下所示：

data "aws_iam_policy_document" "assume_role" {

  statement {
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["eks-fargate-pods.amazonaws.com"]
    }
  }
}

resource "aws_iam_role" "default" {
  name               = var.role_name
  assume_role_policy = join("", data.aws_iam_policy_document.assume_role.json)
  tags               = var.tags
}

resource "aws_iam_role_policy_attachment" "amazon_eks_fargate_pod_execution_role_policy" {
  policy_arn = "arn:aws:iam::aws:policy/AmazonEKSFargatePodExecutionRolePolicy"
  role       = join("", aws_iam_role.default.name)
}

我建议您查看来自 Cloudposse 等很棒社区的一些很棒的示例。

我给你完整的例子fargate profile和eks-node-group，这似乎是你此时需要部署的解决方案。

Pd：试着读一读他们是如何制作模块的，我想你会很快达到你的目标。

希望它对您和其他用户有用。

使用 Terraform 创建实例类型 Fargate 的 EKS 节点组

1 个答案: