Question

我想知道是否可以使用批处理文件获取所选文件的属性。我只发现了一个能够做到这一点的winbatch示例。欢迎任何建议。感谢

Answer 1

对于标准Windows文件属性，请使用WMIC DATAFILE。

某些文件格式（例如ID3标头中的.mp3）具有众所周知的属性。尽管资源管理器可能会显示其中一些，但并非所有这些都可以通过WMIC DATAFILE获得。

最后，自定义文件格式的许多其他文档属性都不会轻松（甚至可能）进行外部访问。

Answer 2

使用VBScript，我能够从我创建的最近的Word 2010文档中显示最后一位作者和经理：

Option Explicit

Const Schema_LastAuthor = "{F29F85E0-4FF9-1068-AB91-08002B27B3D9} 8"
Const Schema_Manager = "{D5CDD502-2E9C-101B-9397-08002B2CF9AE} 14"

Dim Shell
Set Shell = CreateObject("Shell.Application")

If (Not Shell Is Nothing) Then

    Dim ThisFolder
    Set ThisFolder = Shell.NameSpace("YOUR_FOLDER_HERE")

    If (Not ThisFolder Is Nothing) Then

        Dim ThisFolderItem
        Set ThisFolderItem = ThisFolder.ParseName("YOUR_DOCUMENT_HERE")

        If (Not ThisFolderItem Is Nothing) Then

            Dim lastAuthor, manager
            lastAuthor = ThisFolderItem.ExtendedProperty(Schema_LastAuthor)
            manager = ThisFolderItem.ExtendedProperty(Schema_Manager)

            WScript.Echo "   Document:   " & ThisFolderItem.Name
            WScript.Echo "Last author:   " & lastAuthor
            WScript.Echo "    Manager:   " & manager

        End If

        Set ThisFolderItem = Nothing

    End If

    Set ThisFolder = Nothing

End If

Set Shell = Nothing

WScript.Quit

以下是有关documents的Windows Property System架构的更多信息。希望这有帮助！

使用批处理文件获取文件属性

2 个答案: