Question

我是grails的新手，我对限制查询结果有疑问：域用户：

class User {    
    String login
    String password
    String fname
    String lname
    String role = "user"    

    static constraints = {
        login    (size:5..15, blank:false, unique:true, matches:"[a-zA-Z0-9]+")
        password (size:5..15, blank:false)
        fname    (blank:false)
        lname    (blank:false)
        role     (inList:["user", "admin"])
    }

    String toString(){
        fname & " " & lname
    }

    static mapping = {
        cache true

        columns {
            fname     type:'text'
            lname     type: 'text'
            password  type:'text'
            login     type:'text'
        }   
    }
}

我的GSP页面代码段显示结果：

<g:each in="${userInstanceList}" status="i" var="userInstance">
  <tr class="${(i % 2) == 0 ? 'odd' : 'even'}">
    <td><g:link action="show" id="${userInstance.id}">
      ${fieldValue(bean: userInstance, field:   "id")}</g:link></td>
    <td>${fieldValue(bean: userInstance, field: "login")}</td>
    <td>****</td>
    <td>${fieldValue(bean: userInstance, field: "fname")}</td>
    <td>${fieldValue(bean: userInstance, field: "lname")}</td>
    <td>${fieldValue(bean: userInstance, field: "role")}</td>
  </tr>
</g:each>

我使用此代码在单独的gsp视图中调用控制器：

<g:link class="users" controller="user" params="[sort:'fname',order:'desc']" action="">Manager Users</g:link>

我的问题是，如何根据以下标准调用域并显示结果：首先，如果角色是管理员，则显示所有内容。如果角色不是admin，则只显示某个登录值的结果（即，只显示login =当前用户的结果）

感谢您的帮助！杰森

Answer 1

最好的＆amp;全面认证解决方案是Gustavo提出的SpringSecurity插件，但我认为你只需要一个简单的标准示例。在控制器中，您可以将userInstanceList设置为：

def currentUser = User.get(1); // put your current user here
def c = User.createCriteria()
def userInstanceList = c.list {
    or {
        and {
                  ne("role","admin")
                  eq("login",currentUser.login)
                }
        eq("role", "admin")
    }
    maxResults(10)
    order("login", "asc")
}

有关条件的详细信息，请参见here。

Answer 2

定义您的users控制器index操作，例如：

def index = {
    if (isAdmin()) {
        [ userInstanceList: User.list(params) ]
    } else {
        [ userInstanceList: User.findAllByLogin(currentUser.login) ]
    }
}

当然，您需要定义isAdmin()和currentUser，但这取决于您的安全实施。如果使用spring-security-core插件，您可以使用：

import org.codehaus.groovy.grails.plugins.springsecurity.SpringSecurityUtils

class UsersController {

    def springSecurityService

    def index = {
        if (SpringSecurityUtils.ifAllGranted(['ROLE_ADMIN'])) {
            [ userInstanceList: User.list(params) ]
        } else {
            [ userInstanceList: User.findAllByLogin(springSecurityService.currentUser.login) ]
        }
    }

    // ...

}

有关详细信息，请参阅helper classes插件文档中spring-security-core部分。

如何使用条件限制域结果

2 个答案: