Question

我们在Oracle 10g和19c中存在具有相同数据集和设置的相同存储过程。该过程完成了许多数据提取和操作。当我们使用相同的数据集（假设有10000条记录）执行时，它在10g中运行良好，而时间却更少，但在19c中则需要花费很多时间，并且在一段时间后会引发“超出打开游标限制”错误。我们对两个数据库的OPEN_CURSOR和CACHED_CURSOR大小进行了基本比较。

我们还可以从服务器端比较哪些参数或设置来解决此问题？

Answer 1

我无法告诉您是什么原因导致最大的打开游标问题，但是我告诉您如何通过使用GV$OPEN_CURSOR识别相关的会话和SQL语句来查找原因。

如果幸运的话，您可以通过一个简单的查询立即发现问题，该查询计算每个会话中打开的游标的数量。下面的查询中有很多列，请使用IDE，以便您可以轻松浏览所有数据。以我的经验，只需浏览USER_NAME和SQL_TEXT之类的列就足以确定罪魁祸首。

select count(*) over (partition by inst_id, sid) cursors_per_session, gv$open_cursor.*
from gv$open_cursor
order by cursors_per_session desc, inst_id, sid;

请记住，该视图中会有许多奇怪的查询，这些查询可能会使计数超出您的预期。对于所有递归和缓存查询，使用50个游标进行“无聊”会话并不罕见。您正在寻找带有数百个打开的游标的会话。（除非有人愚蠢地将参数值降低到默认值以下。）

不幸的是，GV$OPEN_CURSOR不包含历史数据，如果紧密循环中有异常会迅速打开和消除大量游标，则这些问题会迅速开始和停止。下面的PL / SQL块将一直运行，直到找到具有大量打开的游标的会话，存储数据并退出为止。这个PL / SQL块很昂贵，并且会在等待正确的时刻用完整个处理会话，因此只使用一次就可以发现问题。

--Create table to hold the results.
create table too_many_cursors as
select 1 cursors_per_session, gv$open_cursor.*
from gv$open_cursor
where 1 = 0;


--Write the open cursor data when a session gets more than N open cursors.
declare
    v_open_cursor_threshold number := 50;
    v_count number;
begin
    --Loop forever until the problem is found.
    loop
        --Count the largest numbe of open cursors.
        select max(the_count)
        into v_count
        from
        (
            select count(*) the_count
            from gv$open_cursor
            group by inst_id, sid
        );

        --If the threshold is reached, write the data, commit it, and quit the program.
        if v_count >= v_open_cursor_threshold then

            insert into too_many_cursors
            select *
            from
            (
                select count(*) over (partition by inst_id, sid) cursors_per_session, gv$open_cursor.*
                from gv$open_cursor
            )
            where cursors_per_session >= v_open_cursor_threshold;
            
            commit;
            
            exit;
        end if;
        
    end loop;
end;
/


--Your problem should now be in this table:
select * from too_many_cursors;

如果要测试监视，可以使用下面的PL / SQL块打开大量游标。

--Open a large number of cursors in and wait for 20 seconds.
--(Done by creating a dynamic PL/SQL block with many "open" commands with a "sleep" at the end.
declare
    v_number_of_open_cursors number := 200;
    v_declarations clob;
    v_opens clob;
    v_sql clob;
begin
    for i in 1 .. v_number_of_open_cursors loop
        v_declarations := v_declarations || 'v_cursor'|| i ||' sys_refcursor;' || chr(10);
        v_opens := v_opens || 'open v_cursor' || i || ' for select * from dual;';
    end loop;

    v_sql :=
        'declare '||chr(10)||v_declarations||chr(10)||
        'begin'||chr(10)||v_opens||chr(10)||
        'dbms_lock.sleep(20);'||chr(10)||'end;';

    --Print for debugging.
    --dbms_output.put_line(v_sql);

    execute immediate v_sql;
end;
/

Oracle 19c Open_cursor超出问题

1 个答案: