Question

我正在尝试为Command对象验证编写一些单元测试。当我的命令对象有许多具有许多验证规则的字段时，为每个测试用例设置命令对象会变得过于冗长和重复。

说我有这个命令对象：

class MemberCommand {
    String title
    String name
    String phone
    static constraints = {
        title(blank: false, inList: ["Mr", "Mrs", "Miss", "Ms"])
        name(blank: false, maxSize:25)
        phone(blank: false, matches: /\d{8}/)
    }
}

我想通过这样做来测试这个：

class ValidationTitle extends UnitSpec {
    def "title must be one of Mr, Mrs, Miss, Ms"() {
        setup:
        def memberCommand = new MemberCommand()
        // I don't want to do:
        // memberCommand.name = "Spock" 
        // memberCommand.phone = "99998888"
        // Instead, I want to disable other constraints, except the one for title
        mockForConstraintsTests MemberCommand, [memberCommand]

        when:
        memberCommand.title = t

        then:
        memberCommand.validate() == result

        where:
        t << ["Mr", "Mrs", "Miss", "Ms", "Dr", ""]
        result << [true, true, true, true, false, false]
    }
}

此测试将失败，因为当调用memberCommand.validate（）时，将使用所有约束，并且即使在正在测试标题“Mr”的情况下也会导致验证错误。我可以为这一个测试设置名称和电话，但是，当我测试名称验证时，我需要设置标题和电话，在测试电话验证时我需要设置标题和名称。你可以想象，如果命令对象有更多字段，并且规则更复杂，那么这会变得更加烦人。

有没有办法在Grails中使用Spock进行单元测试中禁用约束？

如果没有，还有其他类似情况的建议吗？

谢谢。

Answer 1

您无法禁用特定约束验证。但是，您可以为其余属性提供有效值，也可以特别检查title属性中的错误。

在第一种情况下，您只需创建一个具有默认（和有效）属性的地图，并从中初始化您的命令：

def validAttributes = [ title: 'Mr', name: 'Spock', phone: '99998888' ]

def "title must be one of Mr, Mrs, Miss, Ms"() {
    setup:
    def memberCommand = new MemberCommand(validAttributes)
    mockForConstraintsTests MemberCommand, [memberCommand]

    when:
    memberCommand.title = t

    then:
    memberCommand.validate() == result

    where:
    t << ["Mr", "Mrs", "Miss", "Ms", "Dr", ""]
    result << [true, true, true, true, false, false]
}

使用“基线”案例进行验证也是一种好习惯（我总是在我的测试中遵循这种模式）。它表达了您对验证的基本假设。

另一种可能性是：

def "title must be one of Mr, Mrs, Miss, Ms"() {
    setup:
    def memberCommand = new MemberCommand()
    mockForConstraintsTests MemberCommand, [memberCommand]

    when:
    memberCommand.title = t
    memberCommand.validate()

    then:
    memberCommand.errors['title'] == result

    where:
    t << ["Mr", "Mrs", "Miss", "Ms", "Dr", ""]
    result << [null, null, null, null, 'not.inList', 'not.inList']
}

在grails命令对象中禁用验证约束以进行单元测试（使用Spock）

1 个答案: