简短答案

Question

本文介绍了Gradle 4.10+的一个有趣的功能，称为源依赖项：

https://blog.gradle.org/introducing-source-dependencies

它允许使用Git（例如GitHub）源代码存储库来建立依赖关系。但是似乎它仅支持Gradle项目作为源依赖项。是否可以使用Maven项目？如果可以，请显示示例。

当我尝试在Maven项目中使用此功能时，无论如何，Gradle都会尝试在其中找到build.gradle文件（使用--info选项运行Gradle时会看到该文件），并失败，并显示以下错误消息：

Git repository at https://github.com/something/something.git did not contain a project publishing the specified dependency.

Answer 1

简短答案

...是：“否”。

在后台，源代码依赖关系是复合构建。这些需要是Gradle项目，因为外部项目已与主项目合并。

长答案

...是：“是，但很难”。

您链接到的同一博客文章中实际上提到了该问题（强调我的意思）：

源依赖性使这些用例更易于实现。 Gradle会自动检查出正确的依赖版本，并确保在需要时生成二进制文件。运行构建的所有地方都会这样做。 检出的项目甚至不需要现有的Gradle构建。 This example显示了通过插件注入Gradle构建，Gradle构建消耗了两个没有构建系统的源依赖项。注入的配置可以执行常规Gradle插件可以执行的任何操作，例如包装现有的CMake或Maven构建。

因为听起来不是在源依赖项中的Maven和Gradle项目之间建立桥梁不是世界上最大的事情，所以我给了一个机会。除了传递依赖之外，我也可以使用。基本上，您将需要做上面链接的示例中显示的操作，但是您无需构建本机库，而是调用Maven（例如，使用Gradle的Maven插件）。

但是，我最终得到的脚本非常复杂，我建议您自己构建Maven项目，将其部署到本地Maven存储库，然后将该存储库添加到Gradle项目中。

好听的答案

好的，这就是实际的操作方法。该功能的文献资料很少，似乎主要针对本机项目（例如C ++或Swift）。

根项目设置

使用已应用Java插件的普通Gradle项目。我在一个空文件夹中执行了“ gradle init”。假设在这个项目中，您依赖于一个名为``的库，以后您希望将其包含为源依赖项：

// [root]/build.gradle
dependencies {
    implementation 'org.example:my-maven-project:1.1'
}

请注意，此处必须定义的版本号必须与存储库中的Git标签匹配。这是将签出的代码修订版。

然后在设置文件中，为其定义源依赖项映射：

// [root]/settings.gradle
rootProject.name = 'my-project'

includeBuild('plugins') // [1]

sourceControl {
    gitRepository("https://github.com/jitpack/maven-simple") { // [2]
        producesModule("org.example:my-maven-project") // [3]
        plugins {
            id "external-maven-build" // [4]
        }
    }
}

[1]：这包括一个名为plugins的Gradle项目，稍后将对其进行解释。
[2]：这只是我发现的一个任意Maven项目，相对简单。替换为您拥有的实际存储库。
[3]：这是我们为其定义源代码构建的Maven模块的名称（与依赖项块中的名称相同）
[4]：这定义了一个external-maven-build项目中定义的名为plugins的自定义设置插件，稍后将对其进行解释。

插件项目结构

在根项目中，我们定义了一个新的Gradle项目。同样，您可以使用gradle init将其初始化为Groovy（或任何您喜欢的项目）项目。删除所有生成的源和测试。

// [root]/plugins/settings.gradle
// Empty, but used to mark this as a stand-alone project (and not part of a multi-build)

// [root]/plugins/build.gradle
plugins {
    id 'groovy'
    id 'java-gradle-plugin' // [1]
}

repositories {
    gradlePluginPortal() // [2]
}

dependencies {
    implementation "gradle.plugin.com.github.dkorotych.gradle.maven.exec:gradle-maven-exec-plugin:2.2.1" // [3]
}

gradlePlugin {
    plugins {
        "external-maven-build" { // [4]
            id = "external-maven-build"
            implementationClass = "org.example.ExternalMavenBuilder"
        }
    }
}

[1]：在这个项目中，我们定义了一个新的Gradle插件。这是执行此操作的标准方法。
[2]：要调用Maven，我正在使用另一个第三方插件，因此我们需要将Gradle插件门户添加为存储库。
[3]：这是用于调用Maven的插件。我不太熟悉它，也不知道如何准备生产。我注意到的一件事是，它不对输入和输出建模，因此不存在对最新检查的内置支持。但这可以追溯添加。
[4]：这定义了自定义插件。请注意，它具有与根项目的设置文件中使用的ID相同的ID。

插件实现类

现在出现了有趣的东西。我选择在Groovy中进行此操作，但是可以使用任何受支持的JVM语言进行此操作。

插件结构与其他Gradle插件一样。要注意的一件事是它是一个设置插件，而您通常使用Project插件。之所以需要这样做，是因为我们基本上是在运行时定义Gradle项目的，而这需要在初始化阶段中完成。

// [root]/plugins/src/main/groovy/org/example/ExternalMavenBuilder.groovy
package org.example

import com.github.dkorotych.gradle.maven.exec.MavenExec
import org.gradle.api.Plugin
import org.gradle.api.artifacts.ConfigurablePublishArtifact
import org.gradle.api.initialization.Settings

class ExternalMavenBuilder implements Plugin<Settings> {
    void apply(Settings settings) {
        settings.with {
            rootProject.name = 'my-maven-project' // [1]
            gradle.rootProject {
                group = "org.example" //[2]
                pluginManager.apply("base") // [3]
                pluginManager.apply("com.github.dkorotych.gradle-maven-exec") // [4]

                def mavenBuild = tasks.register("mavenBuild", MavenExec) {
                    goals('clean', 'package') // [5]
                }

                artifacts.add("default", file("$projectDir/target/maven-simple-0.2-SNAPSHOT.jar")) { ConfigurablePublishArtifact a ->
                    a.builtBy(mavenBuild) // [6]
                }
            }
        }
    }
}

[1]：必须与Maven模块名称匹配
[2]：必须与Maven模块组匹配
[3]：定义诸如“构建”和“清理”之类的任务
[4]：第三方插件，可以更轻松地调用Maven
[5]：有关选项，请参见https://github.com/dkorotych/gradle-maven-exec-plugin
[6]：在“默认”配置中将Maven输出添加为工件

请注意，它不会对传递依赖项进行建模，并且由于缺少输入和输出，它永远不会是最新的。

这是我花了几个小时才玩完的。我认为可以将其概括为发布到Gradle门户的通用插件。但是我认为我已经准备太多了。如果有人想从这里继续，那么我很幸运：）

使用Maven项目作为Gradle源依赖项的Git存储库

1 个答案:

简短答案

长答案

好听的答案

根项目设置

插件项目结构

插件实现类