我查看了似乎与此有关的其他两个问题,但是它们有点晦涩难懂,我无法将它们与我想做的事情联系起来,我认为这很简单。我也认为这将是一个非常常见的问题/任务的清晰陈述,因此我将其发布是为了使其他像我这样的人受益。
我有3个文件,每个文件有key=value
对的列表:
settings1.ini
key1=val1
key2=val2
key3=val3
settings2.ini
key1=val4
key2=val5
key3=val6
settings3.ini
key1=val7
key2=val8
key3=val9
毫不奇怪,我想将这些key=value
对读入哈希表以对其进行操作,所以...
我有文件名的哈希值:
my %files = { file1 => 'settings1.ini'
, file2 => 'settings2.ini'
, file3 => 'settings3.ini'
};
我可以像这样遍历文件名:
foreach my $fkey (keys %files) {
say $files{$fkey};
}
好的。
现在,我想将每个文件中的key=value
对列表添加为散列,作为每个“顶级”文件名键下的子散列,这样我就可以像这样遍历它们: / p>
foreach my $fkey (keys %files) {
say "File: $files{$fkey}";
foreach my $vkey (keys $files{$fkey}) {
say " $vkey: $files{$fkey}{$vkey}";
}
}
换句话说,我想向哈希表添加第二级,以使它不再只是(按伪术语)单层值列表:
file1 => settings1.ini
file2 => settings2.ini
file3 => settings3.ini
成为值的多层列表:
file1 => key1 => 'val1'
file1 => key2 => 'val2'
file1 => key3 => 'val3'
file2 => key1 => 'val4'
file2 => key2 => 'val5'
file2 => key3 => 'val6'
file3 => key1 => 'val7'
file3 => key2 => 'val8'
file3 => key3 => 'val9'
位置:
my $fkey = 'file2';
my $vkey = 'key3';
say $files{$fkey}{$vkey};
将打印值
'val6'
作为旁注,我正在尝试使用File::Slurp
来读取key=value
对。在单级哈希上执行此操作就可以了:
my %new_hash = read_file($files{$fkey}) =~ m/^(\w+)=([^\r\n\*,]*)$/img;
但是-为了解决整个问题-我真正想做的是将key=value
对的新哈希值“嫁接到”在顶部$file
键下方的文件名的现有哈希值中, “子/分支”子哈希。
我use strict;
,所以我已经看到了
Can't use string ("string") as a HASH ref while "strict refs" in use at script.pl line <lineno>.
我不完全了解...
感谢您Timur Shtatland,Polar Bear和Dave Cross的出色回答。在精神上分析您的建议时,我发现我对最初的问题有点不一致,从而使您有些误解。我道歉。我也认为我现在知道为什么看到“严格引用”错误。我做了一些更改。
请注意,我第一次提到文件名 的初始哈希是正确的 。但是,随后的foreach示例遍历%files
是不正确的,因为我从使用file1
作为第一个文件密钥到使用settings1.ini
作为第一个文件密钥成为了错误。我认为这就是Perl引发strict refs
错误的原因-因为我试图将密钥从初始字符串更改为指向子哈希的hash_ref(反之亦然)。
我理解正确吗?
答案 0 :(得分:3)
有几个用于ini文件的CPAN模块。您应该研究可用的东西,并选择自己的内心需求。
否则,您可以按照以下代码段的精神编写自己的代码
use strict;
use warnings;
use feature 'say';
use Data::Dumper;
my @files = qw(settings1.ini settings2.ini settings3.ini);
my %hash;
for my $file (@files) {
$hash{$file} = read_settings($file);
}
say Dumper(\%hash);
sub read_settings {
my $fname = shift;
my %hash;
open my $fh, '<', $fname
or die "Couldn't open $fname";
while( <$fh> ) {
chomp;
my($k,$v) = split '=';
$hash{$k} = $v
}
close $fh;
return \%hash;
}
输出
$VAR1 = {
'settings1.ini' => {
'key2' => 'val2',
'key1' => 'val1',
'key3' => 'val3'
},
'settings2.ini' => {
'key2' => 'val5',
'key1' => 'val4',
'key3' => 'val6'
},
'settings3.ini' => {
'key1' => 'val7',
'key2' => 'val8',
'key3' => 'val9'
}
};
答案 1 :(得分:2)
要一次构建一层哈希,请使用匿名哈希。这里每个%files
的值都是对哈希的引用,例如对于$files{'settings1.ini'}
:
# read the data into %new_hash, then:
$files{'settings1.ini'} = { %new_hash }
您不需要预先将哈希值预先定义为多层(作为哈希值的哈希值)。
此外,避免重新发明轮子。使用Perl模块执行常见任务,在这种情况下,请考虑使用Config::IniFiles之类的内容来解析*.ini
文件
另请参见:
匿名哈希:perlreftut
哈希值:perldsc
答案 2 :(得分:2)
Perl使这种事情变得非常简单。
#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';
use Data::Dumper;
my %files;
# <> reads from the files given on the command line
# one line at a time.
while (<>) {
chomp;
my ($key, $val) = split /=/;
# $ARGV contains the name of the file that
# is currently being read.
$files{$ARGV}{$key} = $val;
}
say Dumper \%files;
以以下方式运行:
$ perl readconf settings1.ini settings2.ini settings3.ini
给出以下输出:
$VAR1 = {
'settings3.ini' => {
'key2' => 'val8',
'key1' => 'val7',
'key3' => 'val9'
},
'settings2.ini' => {
'key3' => 'val6',
'key1' => 'val4',
'key2' => 'val5'
},
'settings1.ini' => {
'key3' => 'val3',
'key1' => 'val1',
'key2' => 'val2'
}
};