尝试在测试引导加载程序上实现硬件中断。异常正在起作用(因此发现它是GPF)。尝试sti
时,发生了GPF。这是我的主要代码:
cli
lgdt [gdt_desc]
lidt [idt_desc]
mov eax, cr0
or eax, 1
mov cr0, eax
jmp 0x8:bit_32
bit_32:
[bits 32]
mov ax, 0x10
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
mov eax, 0x8000
mov esp, eax
mov ebp, esp
sti ; exception raised
这就是我的GDT的样子:
start_gdt:
null:
dd 0x0
dd 0x0
code:
dw 0xffff
dw 0x0
db 0x0
db 10011010b
db 01000000b
db 0x0
data:
dw 0xffff
dw 0
db 0x0
db 10010010b
db 01001011b
db 0x0
gdt_desc:
dw gdt_desc-start_gdt-1
dd start_gdt
这就是我的IDT的样子:
start_idt:
i0:
dw genroutine
dw 0x8
db 0
db 10001110b
dw 0
i1: dw genroutine
dw 0x8
db 0
db 10001111b
dw 0
i2: dw genroutine
dw 0x8
db 0
db 10001110b
dw 0
i3: dw genroutine
dw 0x8
db 0
db 10001111b
dw 0
i5: dw genroutine
dw 0x8
db 0
db 10001111b
dw 0
.
.
;around 50 times, with some modification like for keyboard, GPF etc.
我的PIC设置代码:
mov al, 0x11
out 0x20, al
jmp $+2
jmp $+2
out 0xA0, al
jmp $+2
jmp $+2
mov al, 0x20
out 0x21, al
jmp $+2
jmp $+2
mov al, 0x28
out 0xA1, al
jmp $+2
jmp $+2
mov al, 4
out 0x21, al
mov al, 2
jmp $+2
jmp $+2
out 0xA1, al
jmp $+2
jmp $+2
mov al, 11111101b
out 0x20, al
mov al , 11111101b
jmp $+2
jmp $+2
out 0x21, al
ret
试图在修改IDT中的条目后使sti检查键盘中断,但随后发现sti
导致了GPF异常。
qemu日志:
check_exception old: 0xffffffff new 0xd
1: v=0d e=07c2 i=0 cpl=0 IP=0008:0000000000007c74 pc=0000000000007c74 SP=0010:0000000000008000 env->regs[R_EAX]=0000000000008000
EAX=00008000 EBX=00007e15 ECX=00000022 EDX=00002080
ESI=00007e00 EDI=00000800 EBP=00008000 ESP=00008000
EIP=00007c74 EFL=00000246 [---Z-P-] CPL=0 II=0 A20=1 SMM=0 HLT=0
ES =0010 00000000 000bffff 004b9300 DPL=0 DS [-WA]
CS =0008 00000000 0000ffff 00409a00 DPL=0 CS32 [-R-]
SS =0010 00000000 000bffff 004b9300 DPL=0 DS [-WA]
DS =0010 00000000 000bffff 004b9300 DPL=0 DS [-WA]
FS =0010 00000000 000bffff 004b9300 DPL=0 DS [-WA]
GS =0010 00000000 000bffff 004b9300 DPL=0 DS [-WA]
LDT=0000 00000000 0000ffff 00008200 DPL=0 LDT
TR =0000 00000000 0000ffff 00008b00 DPL=0 TSS32-busy
GDT= 00007d4c 00000017
IDT= 00007e15 0000038f
CR0=00000011 CR2=00000000 CR3=00000000 CR4=00000000
DR0=0000000000000000 DR1=0000000000000000 DR2=0000000000000000 DR3=0000000000000000
DR6=00000000ffff0ff0 DR7=0000000000000400
CCS=00000044 CCD=00008000 CCO=EFLAGS
EFER=0000000000000000
我不知道为什么会发生这种情况,我也不了解它以了解自己。请帮忙。
答案 0 :(得分:4)
我观察到在您的错误输出中您遇到了以下异常:
check_exception old: 0xffffffff new 0xd
1: v=0d e=07c2 i=0 cpl=0 IP=0008:0000000000007c74 ...
重要的部分是,这是一个异常代码为#GP(常规保护错误)的错误代码为0x7c2
。 OSdev Wiki包含有关异常以及如何解释#GP异常的错误代码的摘要:
错误代码0x7c2是二进制11111000 01 0
。位0清楚表示这不是外部原因引起的异常。位1和2为01
,这意味着异常是在访问IDT时引起的。 11111000
是中断向量的索引,0xF8
。这是一个危险信号。您的PIC重映射代码似乎是将主pic重映射为0x20-0x27,将从PIC重映射为0x28-0x2f。除非PIC重新映射代码错误,否则中断0xF8
毫无意义。
在查看PIC重新映射代码时,我发现了一个问题:
mov al, 0x11
out 0x20, al
out 0xA0, al
mov al, 0x20
out 0x21, al
mov al, 0x28
out 0xA1, al
mov al, 4
out 0x21, al
mov al, 2
out 0xA1, al
mov al, 11111101b
out 0x20, al
mov al , 11111101b
out 0x21, al
ret
为清楚起见,我删除了jmp $+2
,因为它们不是必需的。如果您交替更新主PIC端口和从PIC端口,则out
指令将充当所需的延迟。 OSDev Wiki上有一节专门介绍PIC remapping and initialization。您的代码在这里有所不同:
mov al, 4
out 0x21, al ; This is Correct
mov al, 2
out 0xA1, al ; This is Correct
mov al, 11111101b
out 0x20, al ; This is Wrong
mov al , 11111101b
out 0x21, al ; This is Wrong
ret
在将4写入端口0x21和2写入端口0xA1之后,您需要将1写入端口0xA1,将1写入端口0xA2。然后,您可以将中断屏蔽写到端口0x21和端口0xA1,以启用和禁用所需的中断。正确的代码可能类似于:
mov al, 4
out 0x21, al ; This is Correct
mov al, 2
out 0xA1, al ; This is Correct
mov al, 1
out 0xA1, al ; This is Correct
out 0x21, al ; This is Correct
; Now set the PIC masks. Each bit in the mask is 0=enabled interrupt, 1=disabled.
mov al, 0
out 0x21, al ; Enable all interrupts on Slave
out 0xA1, al ; Enable all interrupts on Master
; Now set the PIC masks. Each bit in the mask is 0=enabled interrupt, 1=disabled.
; mov al, 0xfc
; out 0x21, al ; Disable all interrupts on Master except timer and keyboard
; 0xfc = 0b11111100
; mov al, 0xff
; out 0xA1, al ; Disable all interrupts on Slave
ret
通过使用错误的初始化代码,我能够重现您的QEMU异常和中断。我会在0xF8上收到一个中断:
0: v=f8 e=0000 i=0 cpl=0 IP=0008:00007c51 pc=00007c51 ...
由于#GP异常未处理且在我的IDT之外,因此出现了
1: v=0d e=07c2 i=0 cpl=0 IP=0008:00007c51 pc=00007c51 ...
修复后,我开始收到类似于计时器的中断,并带有类似于以下内容的正确条目:
0: v=20 e=0000 i=0 cpl=0 IP=0008:00007c4f pc=00007c4f ...