Question

您好我正在使用Delphi，我有一个带有以下项目的StringList：

我想处理它并制作第二个字符串列表每个元素的出现次数：

45 [2]
015 [1]
A15 [3]

如何使用Delphi执行此操作？

Answer 1

你可以使用字典：

Frequencies := TDictionary <String, Integer>.Create;
try
  // Count frequencies
  for Str in StringList do
    begin
    if Frequencies.ContainsKey (Str) then
      Frequencies [Str] := Frequencies [Str] + 1
    else
      Frequencies.Add (Str, 1);
    end; 

   // Output results to console
   for Str in Frequencies.Keys do
     WriteLn (Str + ': ' + IntToStr (Frequencies [Str]));
finally
  FreeAndNil (Frequencies);
end;

唯一的问题可能是结果出现的顺序完全是随机的，并且依赖于哈希映射的内部工作。

感谢daemon_x获取完整的单位代码：

program Project1;

{$APPTYPE CONSOLE}

uses SysUtils, Classes, Generics.Collections;

var Str: String;
    StringList: TStrings;
    Frequencies: TDictionary <String, Integer>;

begin
  StringList := TStringList.Create;

  StringList.Add('45');
  StringList.Add('A15');
  StringList.Add('015');
  StringList.Add('A15');
  StringList.Add('A15');
  StringList.Add('45');

  Frequencies := TDictionary <String, Integer>.Create;

  try
  // Count frequencies
  for Str in StringList do
    begin
      if Frequencies.ContainsKey (Str) then
        Frequencies [Str] := Frequencies [Str] + 1
      else
        Frequencies.Add (Str, 1);
    end;

   // Output results to console
   for Str in Frequencies.Keys do
     WriteLn (Str + ': ' + IntToStr (Frequencies [Str]));

finally
  StringList.Free;
  FreeAndNil(Frequencies);
end;

end.

Answer 2

我在头上编码了这个，因为我现在还没有安装Delphi。让我知道它对你有用。 Stringlist1是包含项目的原始列表，stringlist2为空，将用于存储您想要的内容。

for i := 0 to stringlist1.Count - 1 do
begin
    if (stringlist2.Values[stringlist1[i]] = '') then
        stringlist2.Values[stringlist1[i]] := '1'
    else
        stringlist2.Values[stringlist1[i]] :=
            IntToStr(StrToInt(stringlist2.Values[stringlist1[i]]) + 1);
end;

Answer 3

对原始列表进行排序
```
list1.sort;
```
创建新列表
```
list2:=TStringList.Create;
```

遍历排序列表以计算每个不同的项目并将计数存储在结果列表的对象字段中（或者如果您还没有使用它，只需将计数类型转换为指针并将其存储为对象）。

previtem:=list1[0];
count:=1;
for i:=1 to list1.count-1 do
 begin
  if list1[i]=previtem then 
    inc(count)
  else
   begin
    list2.addObject(previtem,pointer(count));
    previtem:=list1[i];
    count:=1;
   end;
 end;
list2.addObject(previtem,pointer(count));

最后，再次迭代以将计数添加到字符串

  for i:=0 to list2.count-1 do
    list2.items[i]:=list2[i]+' ['+inttostr(list2.objects[i])+']';

计算项目频率

3 个答案: