Question

基本上，我需要预见知道某个令牌是否存在，但是没有匹配它（即使另一个解析器规则仍然匹配它）。

问题的确切细节是“END-ALL”条款。该语言具有类似“IF”（由“END-IF”关闭），“FOR”（由“END-FOR”关闭）等结构，等等。

但是可以选择使用“END-ALL”全局关闭所有这些开环（因此不需要实际的“END-IF”或“END-FOR”子句）。

无论如何我能正确实现吗？

Answer 1

你可以通过在if（和for - ）语句中创建一个布尔标志，跟踪是否需要消耗ENDALL或者预测是否足够。此布尔标志将传递给与if代码块的末尾匹配的解析器规则。

一个小小的演示：

grammar T;

options {
  output=AST;
}

tokens {
  BLOCK;
  ASSIGN;
}

@parser::members {
  private boolean flag = true;
}

parse
  :  block EOF -> block
  ;

block
  :  stat* -> ^(BLOCK stat*)
  ;

stat
  :  PRINT expression -> ^(PRINT expression)
  |  assignment
  |  ifStat
  ;

assignment
  :  ID '=' expression -> ^(ASSIGN ID expression)
  ;

ifStat
@init{
  boolean consumeEndAll = false;
  if(flag) {
    consumeEndAll = true;
    flag = false;
  }
}
@after {
  if(consumeEndAll) {
    flag = true;
  }
}
  :  IF expression DO block end[consumeEndAll] -> ^(IF expression block)
  ;

expression
  :  NUMBER
  |  TRUE
  |  FALSE
  |  ID
  ;

end [boolean consumeEndAll]
  :                                       END
  |                                       EOF
  |  {consumeEndAll}?=>                   ENDALL
  |  {input.LT(1).getType() == ENDALL}?=> { /* consume no token */ }
  ;

PRINT  : 'print';  
ENDALL : 'endall';
END    : 'end';
IF     : 'if';
DO     : 'do';
TRUE   : 'true';
FALSE  : 'false';
NUMBER : '0'..'9'+ ('.' '0'..'9'+)?;
ID     : ('a'..'z' | 'A'..'Z')+;
SPACE  : (' ' | '\t' | '\r' | '\n') {skip();};

end规则（{ ... }?=>）中的谓词会导致规则消耗ENDALL或仅仅查看是否存在此类令牌，但不要使用它。

有关谓词的更多信息：What is a 'semantic predicate' in ANTLR?

上面的语法生成的解析器将为脚本1和2生成相同的AST：

脚本1

if 1 do
  print a
  if 2 do
    print b
    print c
    if 3 do
    end
  end
end
print d

脚本2

if 1 do
  print a
  if 2 do
    print b
    print c
    if 3 do
endall
print d

即以下AST：

enter image description here

（使用graphviz-dev.appspot.com生成的图片）

您可以使用以下Java类对此进行全部测试：

import org.antlr.runtime.*;
import org.antlr.runtime.tree.*;
import org.antlr.stringtemplate.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String source =
        "if 1 do        \n" +
        "  print a      \n" +
        "  if 2 do      \n" +
        "    print b    \n" +
        "    print c    \n" +
        "    if 3 do    \n" +
        "endall         \n" +
        "print d          ";
    System.out.println(source + "\n------------------\n");
    TLexer lexer = new TLexer(new ANTLRStringStream(source));
    TParser parser = new TParser(new CommonTokenStream(lexer));
    CommonTree tree = (CommonTree)parser.parse().getTree();
    DOTTreeGenerator gen = new DOTTreeGenerator();
    StringTemplate st = gen.toDOT(tree);
    System.out.println(st);
  }
}

在ANTLR中，我可以预先查看特定的令牌而不实际匹配它们吗？

1 个答案:

脚本1

脚本2