Question

我有一张包含以下数据的表格：

NodeId ExternalIds
50     601
56     700,701

如何编写分割ExternalIds-column并返回的SQL语句：

NodeId ExternalIds
50     601
56     700
56     701

我发现了很多用户定义的函数和过程，它们将字符串拆分成表格，但是我无法让它们中的任何一个工作

修改

create table #tmpTable (NodeId int, ExternalIds varchar(50))
insert into #tmpTable (NodeId,ExternalIds) values (50, '600')
insert into #tmpTable (NodeId,ExternalIds) values (56, '700,701')

select NodeId, 
    (SELECT * FROM [dbo].[SplitString](select * from #tmpTable,',') where NodeId=56)from #tmpTable)
where NodeId=56
drop table #tmpTable

其中SplitString基于以下内容：

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

Create FUNCTION [dbo].[SplitString] 
(
    -- Add the parameters for the function here
    @myString varchar(500),
    @deliminator varchar(10)
)
RETURNS 
@ReturnTable TABLE 
(
    -- Add the column definitions for the TABLE variable here
    [id] [int] IDENTITY(1,1) NOT NULL,
    [part] [varchar](50) NULL
)
AS
BEGIN
        Declare @iSpaces int
        Declare @part varchar(50)

        --initialize spaces
        Select @iSpaces = charindex(@deliminator,@myString,0)
        While @iSpaces > 0

        Begin
            Select @part = substring(@myString,0,charindex(@deliminator,@myString,0))

            Insert Into @ReturnTable(part)
            Select @part

    Select @myString = substring(@mystring,charindex(@deliminator,@myString,0)+ len(@deliminator),len(@myString) - charindex(' ',@myString,0))


            Select @iSpaces = charindex(@deliminator,@myString,0)
        end

        If len(@myString) > 0
            Insert Into @ReturnTable
            Select @myString

    RETURN 
END

我正在尝试从数据库中获取Umbraco（cms）的一些数据，这些数据是用逗号分隔的值设计的。

感谢托马斯

Answer 1

select NodeId, 
       S.part
from #tmpTable
  cross apply [dbo].[SplitString](ExternalIds, ',') as S

Answer 2

以下是如何将数据光标移动到所需格式的快速示例。注意，这是一个目前没有使用拆分功能的快速演示。我会发两条评论： - 应避免使用imo光标 - 作为以上评论者的建议尝试避免存储分隔数据

DECLARE @Table TABLE
(
    NodeId int,
    ExternalID int
)
DECLARE @NodeId int
DECLARE @ExternalIds nvarchar(2000)

DECLARE db_cursor CURSOR FOR  
SELECT NodeId, ExternalIDs
from dbo.test

OPEN db_cursor   
FETCH NEXT FROM db_cursor INTO @NodeId, @ExternalIds   

WHILE @@FETCH_STATUS = 0   
BEGIN   
    WHILE (Charindex(',',@ExternalIds)>0)
    Begin
        INSERT INTO @Table (NodeId, ExternalId)
        SELECT @NodeId, 
            Data = ltrim(rtrim(Substring(@ExternalIds,1,Charindex(',',@ExternalIds)-1)))

        SET @externalids = Substring(@ExternalIds,Charindex(',',@ExternalIds)+1,len(@ExternalIds))
    End

    INSERT INTO @Table (NodeId, ExternalId)
    Select @NodeId, Data = ltrim(rtrim(@ExternalIds))

    FETCH NEXT FROM db_cursor INTO @NodeId, @ExternalIds  
END   

CLOSE db_cursor   
DEALLOCATE db_cursor

SELECT * FROM @Table

返回id并拆分逗号分隔值的SQL语句

2 个答案: