Question

├── instance.tf
├── module
│   ├── Network
│   │   ├── output.tf
│   │   ├── resource.tf
│   │   └── vars.tf
│   └── sg
│       ├── output.tf
│       └── resource.tf
├── provider.tf
├── terraform.tfstate
├── terraform.tfstate.backup
└── vars.tf

这是我的项目文件夹结构

我正在尝试创建两个模块，一个用于vpc，另一个用于安全组。这是我的vpc模块输出

output "vpc_id" {
    value = aws_vpc.vpc_dev.id
}
output "public_subnet_id" {
    value = aws_subnet.public_subnet.id 
}
output "private_subnet_id" {
    value = aws_subnet.private_subnet.id
}

安全组模块看起来像

module "NetworkModule" {
    source ="../Network"
}
resource "aws_security_group" "sg_dev" {
    name = "web_sg"
    vpc_id = module.NetworkModule.vpc_id
    ....
    ...}

这是sg模块的输出

output "sg_id" {
    value = aws_security_group.sg_dev.id
}

我正在使用此模块在aws中创建我的实例

module "NetworkModule" {
    source = "./module/Network"
}
module "sgmodule"{
    source = "./module/sg"
}
resource "aws_instance" "web_dev" {
    ami = var.AMIS[var.REGION]
    instance_type = "t2.micro"
    subnet_id = module.NetworkModule.public_subnet_id
    vpc_security_group_ids = ["${module.sgmodule.sg_id}"]
    tags = {
        Name = "web_dev"
    }
}

但是我可以看到与vpc模块相关的所有东西都被创建了两次（例如，我可以看到两个vpc而不是一个，2个公共子网而不是一个，等等）.. am我正在使用右侧的模块道路？ ..

如何在不创建两次资源的情况下使用安全组模块中网络模块的输出？

Answer 1

在instance.tf中，您拥有：

module "NetworkModule" {
    source = "./module/Network"
}
module "sgmodule"{
    source = "./module/sg"
}

在module / sg / resource.tf中，您具有：

module "NetworkModule" {
    source ="../Network"
}

因此，您获得了“网络”模块的两个实例，并将资源增加了一倍。

在Terraform中使用模块就像在其他语言中使用 new 。它再次实例化模块，创建其所需资源的另一个副本。通常这很有用，但您的情况令人惊讶。

您可能应该做的是从module / sg / resource.tf中删除 NetworkModule 模块，并将其替换为变量：

variable "vpc_id" {
    type = string
}

resource "aws_security_group" "sg_dev" {
    name = "web_sg"
    vpc_id = var.vpc_id
    ....
    ...}

然后在instance.tf中将该变量提供给 sgmodule 模块块：

module "sgmodule"{
    source = "./module/sg"
    vpc_id = module.NetworkModule.vpc_id
}

现在，您将拥有所需的依赖关系，而无需重复使用网络基础结构资源。

如何在不创建两次资源的情况下使用安全组模块中网络模块的输出？

1 个答案: