Question

我很难找到一种方法来计算数字列表的中位数和平均值，而Tcl似乎确实限制了在线资源。到目前为止，我只打印了列表中的数字。

非常感谢您的帮助。

proc ladd {l} {
    set total 0
    set counter 0
    foreach nxt $l {
        incr total $nxt
        incr counter 1
    }
    puts "$total"
    puts "$counter"

    set average ($total/$counter)

    puts "$average"


}

set a [list 4 3 2 1 15 6 29]
ladd $a

Answer 1

要获取列表的平均值（即算术平均值），您可以执行以下操作：

proc average {list} {
    expr {[tcl::mathop::+ {*}$list 0.0] / max(1, [llength $list])}
}

对列表中的值求和（结尾的0.0强制结果为浮点值，即使所有添加的数字都是整数）并除以元素数（如果为列表则为1）为空，因此空列表的平均值为0.0，而不是错误。）

要获取列表的中位数，必须对其进行排序并选择中间元素。

proc median {list {mode -real}} {
    set list [lsort $mode $list]
    set len [llength $list]
    if {$len & 1} {
       # Odd number of elements, unique middle element
       return [lindex $list [expr {$len >> 1}]]
    } else {
       # Even number of elements, average the middle two
       return [average [lrange $list [expr {($len >> 1) - 1] [expr {$len >> 1}]]]
    }
}

要完成设置，请按照以下方法在唯一的列表中获取列表模式（与某些应用程序有关，该应用程序是从相当小的集合中选择值的）：

proc mode {list} {
    # Compute a histogram
    foreach val $list {dict incr h $val}
    # Sort the histogram in descending order of frequency; type-puns the dict as a list
    set h [lsort -stride 2 -index 1 -descending -integer $h]
    # The mode is now the first element
    return [lindex $h 0]
}

作为练习，我将处理空的和非唯一的案件。

在tcl中查找列表的中位数和平均值

1 个答案: