Question

我还有一个关于Wolfram Mathematica的问题。有人知道如何在y轴上绘制图形吗？

我希望这个数字有所帮助。

enter image description here

Answer 1

ParametricPlot[{5 Sin[y], y}, {y, -2 \[Pi], 2 \[Pi]}, 
                Frame -> True,  AxesLabel -> {"x", "y"}]

enter image description here

编辑

到目前为止给出的答案都不能与Plot的Filling选项一起使用。在这种情况下，Plot的输出包含GraphicsComplex（顺便提一下，打破了Mr.Wizard的替换）。要获得填充功能（它不适用于没有填充的标准图），您可以使用以下内容：

Plot[Sin[x], {x, 0, 2 \[Pi]}, Filling -> Axis] /.  List[x_, y_] -> List[y, x]

enter image description here

Plot[{Sin[x], .5 Sin[2 x]}, {x, 0, 2 \[Pi]}, Filling -> {1 -> {2}}] 
   /. List[x_, y_] -> List[y, x]

enter image description here

Answer 2

您可以在使用Reverse：

绘图后翻转轴

g = Plot[Sin[x], {x, 0, 9}];

Show[g /. x_Line :> Reverse[x, 3], PlotRange -> Automatic]

enter image description here

稍作修改，这适用于使用Filling的情节：

g1 = Plot[{Sin[x], .5 Sin[2 x]}, {x, 0, 2 \[Pi]}];
g2 = Plot[{Sin[x], .5 Sin[2 x]}, {x, 0, 2 \[Pi]}, Filling -> {1 -> {2}}];

Show[# /. x_Line | x_GraphicsComplex :> x~Reverse~3,
     PlotRange -> Automatic] & /@ {g1, g2}

enter image description here

（用:>替换MapAt[#~Reverse~2 &, x, 1]的RHS可能更强大

作为一种功能

这是我建议使用的表格。它包括翻转原始PlotRange而不是强制PlotRange -> All：

axisFlip = # /. {
   x_Line | x_GraphicsComplex :> 
      MapAt[#~Reverse~2 &, x, 1], 
   x : (PlotRange -> _) :>
      x~Reverse~2 } &;

使用方式如：axisFlip @ g1或axisFlip @ {g1, g2}

Rotate可以产生不同的效果：

Show[g /. x_Line :> Rotate[x, Pi/2, {0,0}], PlotRange -> Automatic]

enter image description here

Answer 3

一种可能性是使用这样的ParametricPlot：

ParametricPlot[
  {-y*Exp[-y^2], y}, {y, -0.3, 4},
  PlotRange -> {{-2, 2}, All},
  AxesLabel -> {"x", "y"},
  AspectRatio -> 1/4
]

Example for plot with flipped axes

Answer 4

只是为了好玩：

ContourPlot 是另一种选择。使用Thies函数：

ContourPlot[-y*Exp[-y^2/2] - x == 0, 
            {x, -2, 2}, {y, 0, 4}, 
            Axes -> True, Frame -> None]

enter image description here

RegionPlot 是另一个

RegionPlot[-y*Exp[-y^2/2] > x,
           {x, -2.1, 2.1}, {y, -.1, 4.1}, 
           Axes -> True, Frame -> None, PlotStyle -> White, 
           PlotRange -> {{-2, 2}, {0, 4}}]

enter image description here

最后，使用ListCurvePathPlot和Solve的真的令人费解的方式：

Off[Solve::ifun, FindMaxValue::fmgz];

ListCurvePathPlot[
 Join @@
  Table[
        {x, y} /. Solve[-y*Exp[-y^2/2] == x, y],
   {x, FindMaxValue[-y*Exp[-y^2/2], y], 0, .01}],
 PlotRange -> {{-2, 2}, {0, 4}}]

On[Solve::ifun, FindMaxValue::fmgz];

enter image description here

关闭主题

回答Sjoerd的None of the answers given thus far can work with Plot's Filling option。

回复：没必要

f={.5 Sin[2 y],Sin[y]};
RegionPlot[Min@f<=x<=Max@f,{x,-1,1},{y,-0.1,2.1 Pi},
  Axes->True,Frame->None,
  PlotRange->{{-2,2},{0,2 Pi}},
  PlotPoints->500]

enter image description here

Answer 5

根据您希望轴标签显示的方式，您可以在Rotate函数中包装原始Plot的代码。

在Mathematica中绘制y轴

5 个答案:

作为一种功能