路径名构造函数

Question

我想加载一个位于当前工作文件夹子目录中的Lisp脚本。相对路径为 ./ crossover-operators / ER.lisp 。

在Linux中，这是通过以下方式完成的：

(load "./crossover-operators/ER.lisp")

在Windows中，通过以下方式完成：

(load ".\\crossover-operators\\ER.lisp")

如何创建一个独立于运行Common Lisp脚本的操作系统来加载 ER.lisp 脚本的函数？

Answer 1

首先，19.1.1 Namestrings as Filenames说，确实，名称字符串（字符串作为路径名）是不可移植的。

符合标准的程序绝不能无条件地使用逻辑路径名字符串之外的文字名称字符串，因为Common Lisp除了定义了可保证可移植的逻辑路径名之外，没有定义任何名称字符串语法。

还请注意，如果您要求用户提供文件名，则可以方便地使用它们：

但是，如果小心，符合标准的程序可以成功地处理用户提供的包含或引用非便携式名称字符串的数据。

您有两个选择，它们不是彼此排斥的：使用路径名构造函数和/或使用逻辑路径名。

路径名构造函数

使用make-pathname，merge-pathnames构建路径名。路径名是具有可以组合在一起的不同组件（目录，名称，类型等）的结构。它们使用prototypal inheritance方法构建，您可以在其中通过复制现有路径名并更改其某些组件来创建新路径名。

make-pathname类似于struct构造函数，不同之处在于它有一个:defaults参数，该参数给出了用作原型的路径名。

merge-pathnames有所不同，因为它还执行语义操作。

例如，如果*default-pathname-defaults*（保存默认路径名的特殊变量）的设置如下：

USER> (setf *default-pathname-defaults*
            (make-pathname :directory '(:relative "crossover-operator")))
#P"crossover-operator/"

然后您会有两种不同的行为。

USER> (make-pathname :directory '(:relative "tmp")  
                     :defaults *default-pathname-defaults*)
#P"tmp/"

make-pathname替换原始路径名的目录部分。

USER> (merge-pathnames *)
#P"crossover-operator/tmp/"

merge-pathnames采用一个路径名（此处为我们刚刚构建的路径名，用*表示），并相对于*default-pathname-defaults*中的目录合并目录。

逻辑路径名

逻辑路径名有点像URL（统一资源定位符），并且仅间接表示文件。程序员必须根据地址的HOST部分，从逻辑路径名到实际物理路径名定义翻译功能。

路径名（名称字符串）的打印表示形式不可移植，对于逻辑路径名，除外。参见19.3.1 Syntax of Logical Pathname Namestrings。

除了具有定义的语法和转换功能（从逻辑路径名到物理路径名）之外，它们的行为与其他路径名相同，因此您可以如上所述调用merge-pathnames。

路径名转换可以映射到不可移植的名称字符串（但是您可以在不同的主机上以不同的方式设置转换），也可以映射到逻辑或物理路径名。 LOGICAL-PATHNAME-TRANSLATIONS的超级规格中有一些有关如何使用逻辑路径名的示例，例如：

 ;;;A more complex example, dividing the files among two file servers
 ;;;and several different directories.  This Unix doesn't support
 ;;;:WILD-INFERIORS in the directory, so each directory level must
 ;;;be translated individually.  No file name or type translations
 ;;;are required except for .MAIL to .MBX.
 ;;;The namestring syntax on the right-hand side is implementation-dependent.
 (setf (logical-pathname-translations "prog")
       '(("RELEASED;*.*.*"        "MY-UNIX:/sys/bin/my-prog/")
         ("RELEASED;*;*.*.*"      "MY-UNIX:/sys/bin/my-prog/*/")
         ("EXPERIMENTAL;*.*.*"    "MY-UNIX:/usr/Joe/development/prog/")
         ("EXPERIMENTAL;DOCUMENTATION;*.*.*"
                                  "MY-VAX:SYS$DISK:[JOE.DOC]")
         ("EXPERIMENTAL;*;*.*.*"  "MY-UNIX:/usr/Joe/development/prog/*/")
         ("MAIL;**;*.MAIL"        "MY-VAX:SYS$DISK:[JOE.MAIL.PROG...]*.MBX")))

 ;;;Sample use of that logical pathname.  The return value
 ;;;is implementation-dependent.          
 (translate-logical-pathname "prog:mail;save;ideas.mail.3")
=>  #P"MY-VAX:SYS$DISK:[JOE.MAIL.PROG.SAVE]IDEAS.MBX.3"

Answer 2

基于@coredump答案和其他研究，一个快速的答案是：

(load (make-pathname :name "ER"
                     :type "lisp"
                     :defaults (make-pathname :directory '(:relative "crossover-operators"))))

路径名独立于Common Lisp中的操作系统

2 个答案:

路径名构造函数

逻辑路径名