Question

下面的代码显示了特定服务器目录中每个图像的缩略图，当我点击图像时，它会弹出一张漂亮的全尺寸图片。它运作得很好。

但是，我希望能够删除图像。我首先想到我可以在页面底部有一个按钮，每个图像旁边都有一个复选框，根据文件名给它一个唯一ID，但是由于它们是动态创建的，我无法想象如何处理按钮上的Click事件用于随机命名的Checkbox ID。然后我尝试在每个项目旁边添加一个按钮，然后尝试使用OnClick＆amp; amp; OnServerClick调用Sub但这也不起作用。

欢迎任何/所有建议：）

Private Sub ImageList()
        If Directory.Exists(Server.MapPath("JobImages\" & DBC_JOB_JobID.Text)) Then
            Dim MySB As New StringBuilder
            Dim dirInfo As New DirectoryInfo(Server.MapPath("JobImages\" & DBC_JOB_JobID.Text))
            MySB.Append("<ul class=""clearfix"">")
            MySB.AppendLine()
            For Each File In dirInfo.GetFiles()
                MySB.Append("<li><a rel=""jobpic"" href=""JobImages\" & DBC_JOB_JobID.Text & "\" & File.Name & """><img src=""JobImages\" & DBC_JOB_JobID.Text & "\Thumbs\" & File.Name & """ width=""150"" height=""100"" /> <span class=""size"">" & File.Name & " </span></a></li>")
                MySB.AppendLine()
            Next
            MySB.Append("</ul>")
            MySB.AppendLine()
            lblMyPictures.Text = MySB.ToString
        End If
    End Sub

Answer 1

确定Kendrick正在谈论的内容（基本上）是使用服务器端控件来跟踪要删除的文件。你现在正在做的是将标记转储到Label控件中，该控件在回发时不会在服务器端触发事件。但是，您可以使用服务器端控件轻松完成此操作。

基本思想是使用容器控件，例如Panel，并将每个子控件添加到它。然后使用标识该行的数据（例如文件名）将事件挂钩到每一行。

标记：

    <asp:Panel ID="pnlList" runat="server">
    </asp:Panel>

代码隐藏：

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    If Directory.Exists(Server.MapPath("Files")) Then
        Dim objDirInfo As New DirectoryInfo(Server.MapPath("Files"))
        For Each objFile As FileInfo In objDirInfo.GetFiles()
            Dim objLabel As New Label
            objLabel.Text = objFile.Name

            Dim objLinkButton As New LinkButton
            objLinkButton.Text = "Delete"
            objLinkButton.CommandName = "Delete"
            objLinkButton.CommandArgument = objFile.Name
            AddHandler objLinkButton.Command, AddressOf DeleteFile

            Dim objLiteral As New LiteralControl
            objLiteral.Text = "<br/>"

            pnlList.Controls.Add(objLabel)
            pnlList.Controls.Add(objLinkButton)
            pnlList.Controls.Add(objLiteral)
        Next
    End If

End Sub

Public Sub DeleteFile(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.CommandEventArgs)
    If e.CommandName = "Delete" Then
        Dim strFileName As String = Server.MapPath("Files\" & e.CommandArgument)
        If File.Exists(strFileName) Then
            Dim objFile As New FileInfo(strFileName)
            objFile.Delete()
        End If
    End If
End Sub

Answer 2

这将是一个很好的例子，说明使用数据意识会让你的生活变得更轻松。

也就是说，如果您不想使用服务器端控件，则可以为每个复选框分配一个ID（即DeleteImage_1），然后将ID和关联的图像名称存储在页面的视图状态中。浏览选中的复选框，并在点击删除按钮时返回查看状态，查看每个ID的名称。

从目录中删除动态填充的图像（非GridView）ASP.NET（VB）

2 个答案: