Question

在OCaml自定义顶层中，有没有办法以#编程方式将提示设置为其他内容？我希望能够更改它以响应用户的最后一个自定义函数（有点像bash如何设置PS1）。我甚至找不到#directive来改变它。谢谢！

Answer 1

在toplevel / toploop.ml中：

let prompt =
  if !Clflags.noprompt then ""
  else if !first_line then "# "
  else if Lexer.in_comment () then "* "
  else "  "
in

但是等等！计算出的提示传递给!read_interactive_input，并导出此引用：

在toplevel / toploop.mli：

(* Hooks for external line editor *)

val read_interactive_input : (string -> string -> int -> int * bool) ref

所以你似乎要做的就是将Toploop.read_interactive_input的值从默认值更改为忽略传递的提示的函数，然后打印出你想要的那个。

read_interactive_input的默认值为：

let read_input_default prompt buffer len =
  output_string Pervasives.stdout prompt; flush Pervasives.stdout;
  let i = ref 0 in
  try
    while true do
      if !i >= len then raise Exit;
      let c = input_char Pervasives.stdin in
      buffer.[!i] <- c;
      incr i;
      if c = '\n' then raise Exit;
    done;
    (!i, false)
  with
  | End_of_file ->
      (!i, true)
  | Exit ->
      (!i, false)

所以你可以使用：

# let my_read_input prompt buffer len =
  output_string Pervasives.stdout  "%%%" ; flush Pervasives.stdout;
  let i = ref 0 in
  try
    while true do
      if !i >= len then raise Exit;
      let c = input_char Pervasives.stdin in
      buffer.[!i] <- c;
      incr i;
      if c = '\n' then raise Exit;
    done;
    (!i, false)
  with
  | End_of_file ->
      (!i, true)
  | Exit ->
      (!i, false)
                                  ;;
val my_read_input : 'a -> string -> int -> int * bool = <fun>
# Toploop.read_interactive_input := my_read_input ;;
- : unit = ()
%%%

在OCaml自定义顶层中设置提示

1 个答案: