Question

我正在编写TF代码以在GCP中创建多个磁盘。目的是使用简明的代码并以列表作为输入。

我的变量app_disks具有以下定义

variable "app_disks" {
  type = list(object({
    name = string
    size = number
  }))
}

在我的main.tf中，即时通讯使用了这样的变量

  app_disks = [
    {
      name = loki
      size = 200
    },
    {
      name = repo
      size = 100
    }
  ]

在我的模块中，我的disk.tf看起来像这样

locals {
  app_disk_map = {
    for disk in var.app_disks : "${disk.name}" => disk
  }
}

resource "google_compute_resource_policy" "app_disk_backup" {
  for_each = local.app_disk_map

  name   = "${each.value.name}-backup"

  snapshot_schedule_policy {
    schedule {
      hourly_schedule {
        hours_in_cycle = 8
        start_time     = "04:00"
      }
    }
    retention_policy {
      max_retention_days    = 14
      on_source_disk_delete = "APPLY_RETENTION_POLICY"
    }
  }
}

resource "google_compute_disk" "app_disk" {
  for_each = local.app_disk_map

  provider = google-beta

  name = each.value.name
  zone = "${var.region}-a"
  size = each.value.size

  resource_policies = [each.google_compute_resource_policy.app_disk_backup[${each.value.name}-backup].self_link]
}

我不确定如何将磁盘的resource_policies链接到相关的google_compute_resource_policy"。

我尝试过类似的组合

each.google_compute_resource_policy.app_disk_backup[${each.value.name}-backup].self_link

each.google_compute_resource_policy.app_disk_backup."${each.value.name}-backup".self_link

但是似乎没有任何作用

Answer 1

我不确定是否能正确解决问题（因为缺少错误输出），但是据我了解，您希望获得以下参考：google_compute_resource_policy.app_disk_backup[each.key].self_link，因此资源看起来像这样：< / p>

resource "google_compute_disk" "app_disk" {
  for_each = local.app_disk_map

....

  resource_policies = [google_compute_resource_policy.app_disk_backup[each.key].self_link]
}

这将引用用于创建依赖资源并在依赖之间创建1：1映射的相同键。

使用for_each通过列表输入创建多个磁盘及其快照

1 个答案: