Question

我写了我的AppleScript应用程序来隐藏我的wifi卡的窗口。我遇到了一些问题，检查窗口是否可见（为了避免命令+ h按键没有效果），所以我决定使用delay 15来制作（根本不是）确保窗口弹出。如果我从编辑器运行脚本或双击应用程序文件，它可以工作，但如果我将其设置为从用户登录开始（在设置＆gt;帐户＆gt;登录元素下），它就不起作用！我尝试更改applescript编辑器的Save as...页面中的复选框：我尝试了only execute的设置，但任何内容都有所改变。事实上，start screen选项可以正常使用，但它会向我发出确认信息，我不想要它（我会优先按cmd + h）。任何人都可以解释我为什么会遇到这个问题？

tell application "System Events"
set progList to (name of every process)
set cond to false
repeat while cond is false
    if (progList contains "WirelessUtilityCardbusPCI") is true then
        delay 5
        activate application "WirelessUtilityCardbusPCI.app"
        tell application "System Events" to keystroke "h" using [command down]
        set cond to true
    else
        delay 5
        set progList to (name of every process)
    end if
end repeat
end tell

编辑：现在它似乎工作了！我忘了重新set progList to (name of every process)。现在代码是正确的。

Answer 1

我看到你的代码正在运行。那很棒。但是我发布这个是为了帮助你学习。我看到你的代码有几个小问题。例如，在你的重复循环中，你告诉系统事件按键“h”。没有必要告诉系统事件在该行中执行此操作，因为您已经在系统事件中告诉代码块，因此系统事件已经知道这样做。

以下是我编写代码的方法。这不需要击键，这总是一件好事，并且效率更高一些。它的工作原理是因为如果进程不存在那么“将theProcess设置为”行错误，则代码进入“on error”部分以延迟5，然后repeat循环尝试再次找到该进程。如果找到该进程，则它将其可见属性设置为与隐藏它相同。

它还有一个超时机制来阻止脚本永远运行。如果你愿意，可以使用它。祝你好运。

set processName to "WirelessUtilityCardbusPCI"
set maxTime to 180 -- we only check for 3 minutes, then end

set inTime to current date
repeat
    try
        tell application "System Events"
            set theProcess to first process whose name is processName
            set visible of theProcess to false
        end tell
        exit repeat
    on error
        if (current date) - inTime is greater than maxTime then
            tell me
                activate
                display dialog "The process " & processName & " could not be found!" buttons {"OK"} default button 1 with icon 0
            end tell
            exit repeat
        end if
        delay 5
    end try
end repeat

编辑：我使用TextEdit应用程序检查了上面的代码，它运行正常。要使用您的应用程序进行检查，请运行以运行此代码时，请确保应用程序正在运行。如果出现错误，将显示该错误。如果没有错误2将显示对话框，显示进度。报告你的发现。

set processName to "WirelessUtilityCardbusPCI"

try
    tell application "System Events"
        set theProcess to first process whose name is processName
        display dialog "I have found the process"
        set visible of theProcess to false
        display dialog "I just performed the \"set visible\" code"
    end tell
on error theError number errorNumber
    tell me
        activate
        display dialog "There was an error: " & (errorNumber as text) & return & return & theError buttons {"OK"} default button 1 with icon stop
        return
    end tell
end try

Answer 2

我已经使用登录项在登录时成功启动AppleScript小程序，因此我的第一个建议是确保不正在运行。让它显示一个自定义对话框或哔哔声或类似的东西，以确认它是否正在运行。

除此之外，我不确定提供什么建议，除非你想发布你在剧本中执行的代码。

Applescript在OSX启动时不起作用

2 个答案: