Question

完全重复：

我在网络上的服务器上有一个名为“dump”的文件夹。每天都有很多临时文件和文件夹保存在该文件夹中。

我想删除这些文件和子文件夹。条件是我要在文件和文件之前一小时删除文件夹只是我们在运行批处理文件之前的当前时间之一。

这意味着我想将一个文件保存在该文件夹中以运行其他ACTIVITIES。就像现在这样。

转到文件夹并按时间列出文件
获取当前时间
删除比当前时间早1小时的文件

Answer 1

在这种情况下，我认为最好使用PowerShell或WSH（如Rihan Meij所述）。比较数据和时间是可能的，但非常脆弱（因为没有办法在批处理文化中获得数据/时间）。你可以这样写：

setlocal enableextensions
set Now=%date%
set NowTime=%time:~0,-3%
call :tokenize_date %Now%
call :tokenize_time %NowTime%
echo %YEAR%-%MONTH%-%DAY%T%HOUR%:%MINUTE%:%SECOND%
call :one_hour_before %Now% %NowTime%
echo %RESULT_DATE% %RESULT_TIME%
ping -n 1 -w 1500 ::1>NUL
set Now2=%date%
set NowTime2=%time:~0,-3%
call :date_time_compare %Now% %NowTime% %Now2% %NowTime2%
echo %Now%T%NowTime% compared to %Now2%T%NowTime2%: %RESULT%
endlocal
goto :eof

:tokenize_date
    rem assuming ISO 8601 date format YYYY-MM-DD
    setlocal enableextensions
    set arg=%1
    set YEAR=%arg:~0,4%
    set MONTH=%arg:~5,2%
    set DAY=%arg:~8,2%
    endlocal&set YEAR=%YEAR%&set MONTH=%MONTH%&set DAY=%DAY%
goto :eof

:tokenize_time
    rem assuming ISO-8601 time format HH:MM:SS, 24-hour
    setlocal enableextensions
    set arg=%1
    set HOUR=%arg:~0,2%
    set MINUTE=%arg:~3,2%
    set SECOND=%arg:~6,2%
    endlocal&set HOUR=%HOUR%&set MINUTE=%MINUTE%&set SECOND=%SECOND%
goto :eof

:one_hour_before
    rem gets a date as %1 and a time as %2
    rem returns a date in RESULT_DATE and a time in RESULT_TIME
    setlocal enabledelayedexpansion enableextensions
    set months=31 28 31 30 31 30 31 31 30 31 30 31
    set i=0
    for %%x in (%months%) do (
        set /a i+=1
        set month_length_!i!=%%x
    )
    call :tokenize_date %1
    call :tokenize_time %2
    set /a HOUR-=1
    if %HOUR% LSS 0 (
        set /a DAY-=1
        set /a HOUR+=24
        if %DAY% LSS 0 (
            set /a MONTH-=1
            if %MONTH% LSS 0 (
                set /a YEAR-=1
                set /a MONTH+=12
            )
            set /a DAY+=month_length_!MONTH!
        )
    )
    endlocal&set RESULT_DATE=%YEAR%-%MONTH%-%DAY%&set RESULT_TIME=%HOUR%:%MINUTE%:%SECOND%
goto :eof

:date_time_compare
    rem expects %1 - date 1, %2 - time 1, %3 - date 2, %4 - time 2
    rem returns a value < 0 if datetime1 is earlier than datetime2
    rem                 > 0                 later than
    rem                 = 0                 equal to
    rem the return value is saved in the variable %RETURN%
    setlocal enableextensions
    call :tokenize_date %3
    call :tokenize_time %4
    set YEAR2=%YEAR%
    set MONTH2=%MONTH%
    set DAY2=%DAY%
    set HOUR2=%HOUR%
    set MINUTE2=%MINUTE%
    set SECOND2=%SECOND%
    call :tokenize_date %1
    call :tokenize_time %2
    if %YEAR2% GTR %YEAR% (endlocal&set RESULT=-1&goto :eof) else (
        if %YEAR2% LSS %YEAR% (endlocal&set RESULT=1&goto :eof) else (
            if %MONTH2%%DAY2%%HOUR2%%MINUTE2%%SECOND2% GTR %MONTH%%DAY%%HOUR%%MINUTE%%SECOND% (
                endlocal&set RESULT=-1&goto :eof
            ) else (
                if %MONTH2%%DAY2%%HOUR2%%MINUTE2%%SECOND2%==%MONTH%%DAY%%HOUR%%MINUTE%%SECOND% (
                    endlocal&set RESULT=0&goto :eof
                ) else (
                    endlocal&set RESULT=1&goto :eof
                )
            )
        )
    )
goto :eof

抱歉，它已经有点长了。比较日期/时间现在只进行了部分测试，但应该有效。小心它包含sub-seconds的时间，因为那里引入了逗号，这扰乱了被调用子程序的参数顺序（因此%time:~0,-3%避免了这种情况）。

之后，您可以使用%~tI扩展来获取日期和时间，将它们与当前减去一小时进行比较并删除（如果适用）。

注1：我假设ISO 8601的日期和时间格式为24小时，这就是我在这里使用的。对于非标准日期格式，您必须稍微改变子程序（但12小时的时间可能会很痛苦）。

注2：目前，代码并不关心闰年。我想是:one_hour_before中的另外5或6行代码。

Answer 2

我知道我知道您尝试做的事情的唯一方法是使用for命令和~t扩展参数。

for %r in (*.*) DO echo %r "created on" %~tr

产生：

C:\>echo BOOTSECT.BAK "created on" 2009/02/17 11:59 PM
BOOTSECT.BAK "created on" 2009/02/17 11:59 PM

C:\>echo config.sys "created on" 2006/09/18 11:43 PM
config.sys "created on" 2006/09/18 11:43 PM

我认为更可能的情况是涉及使用Windows脚本主机或powershell，但你没有提到那些是你的选择，所以我假设有充分的理由，因为无法使用这些技术

编写批处理文件以按日期和时间删除文件夹

完全重复：

2 个答案: