Question

我想将值设为键，键值为值。这样做的最佳方法是什么？

Answer 1

改编自http://www.dreamincode.net/forums/topic/46400-swap-hash-values/：

假设您的哈希值存储在$hash：

中

while (($key, $value) = each %hash) {
   $hash2{$value}=$key;
}

%hash=%hash2;

似乎可以通过反向实现更优雅的解决方案（http://www.misc-perl-info.com/perl-hashes.html#reverseph）：

%nhash = reverse %hash;

请注意，对于反向，重复的值将被覆盖。

Answer 2

使用reverse：

use Data::Dumper;

my %hash = ('month', 'may', 'year', '2011');
print Dumper \%hash;
%hash = reverse %hash;
print Dumper \%hash;

Answer 3

如上所述，最简单的是

my %inverse = reverse %original;

如果多个元素具有相同的值，则“失败”。你可以创建一个HoA来处理这种情况。

my %inverse;
push @{ $inverse{ $original{$_} } }, $_ for keys %original;

Answer 4

my %orig_hash = (...);
my %new_hash;

%new_hash = map { $orig_hash{$_} => $_ } keys(%orig_hash);

Answer 5

所以你想要反向键和哈希中的val？所以使用反向...;）

%hash2 = reverse %hash;

还原（k1 =＆gt; v1，k2 =＆gt; v2） - yield（v2 =＆gt; k2，v1 =＆gt; k1） - 这就是你想要的。 ;）

Answer 6

映射键解决方案更灵活。如果您的价值不是一个简单的价值怎么办？

my %forward;
my %reverse;

#forward is built such that each key maps to a value that is a hash ref:
#{ a => 'something', b=> 'something else'}

%reverse = map { join(',', @{$_}{qw(a b)}) => $_ } keys %forward;

Answer 7

以下是使用Hash::MultiValue执行此操作的方法。

use experimental qw(postderef);

sub invert {
  use Hash::MultiValue;
  my $mvh = Hash::MultiValue->from_mixed(shift);

  my $inverted;    
  $mvh->each( sub { push $inverted->{ $_[1] }->@* , $_[0] } ) ;
  return $inverted;
}

为了测试这个，我们可以尝试以下方法：

my %test_hash = (
  q => [qw/1 2 3 4/],
  w => [qw/4 6 5 7/],
  e => ["8"],
  r => ["9"],
  t => ["10"],
  y => ["11"],
);

my $wow  = invert(\%test_hash);
my $wow2 = invert($wow);

use DDP;
print "\n \%test_hash:\n\n" ;
p %test_hash;
print "\n \%test_hash inverted as:\n\n" ;
p $wow ;

# We need to sort the contents of the multi-value array reference
# for the is_deeply() comparison:
map { 
   $test_hash{$_} = [ sort { $a cmp $b || $a <=> $b } @{ $test_hash{$_} } ] 
} keys %test_hash ; 

map { 
   $wow2->{$_} = [ sort { $a cmp $b || $a <=> $b } @{ $wow2->{$_} } ] 
} keys %$wow2 ; 

use Test::More ;
is_deeply(\%test_hash, $wow2, "double inverted hash == original");
done_testing;

附录

请注意，为了在此处传递花哨的测试，invert()函数依赖于%test_hash将数组引用作为值。要解决此问题，如果您的哈希值不是数组引用，则可以强制使用＃34;常规/混合哈希成为一个多值哈希，Hash::MultiValue然后可以加入一个对象。但是，这种方法意味着即使单个值也会显示为数组引用：

for ( keys %test_hash )  { 
     if ( ref $test_hash{$_} ne 'ARRAY' ) { 
           $test_hash{$_}  = [ $test_hash{$_} ] 
     } 
}

这是一个简写：

ref($_) or $_ = [ $_ ] for values %test_hash ;

这只需要进行往返旅行。测试通过。

Answer 8

假设您的所有值都是简单且唯一的字符串，这里有一种更简单的方法。


%hash = ( ... );
@newhash{values %hash} = (keys %hash);

这称为散列切片。由于您使用 %newhash 生成键列表，因此将 % 更改为 @。

与 reverse() 方法不同，这将按照它们在原始散列中的顺序插入新的键和值。 keys 和 values 总是以相同的顺序返回它们的值（与 each 一样）。

如果您需要对其进行更多控制，例如对其进行排序以便重复值获得所需的键，请使用两个哈希切片。


%hash = ( ... );
@newhash{ @hash{sort keys %hash} } = (sort keys %hash);

在Perl中反转Hash的键和值

8 个答案:

附录