Question

我有xml：

<people>
  <man age="20" />
  <man age="40" />
  <man age="30" />
  <man age="80" />
<people>

使用xsl我试图输出：

first age:20
first and second age (combined): 60
first second and third age(combined) :110
first second third and fouth age(combined) :190

我知道如何选择年龄，但我如何将它们加在一起并写出来？

另请注意，<man>元素可能不仅仅是4。

Answer 1

好的，我刚刚读到你只需要这些数字，所以以下剥离了xslt

<xsl:stylesheet
        version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes" />

    <xsl:variable name="elements" select="/people/man"/>
    <xsl:variable name="count" select="count($elements)"/>

    <!-- Main Entry point -->
    <xsl:template match="/">
        <xsl:call-template name="addthem">
            <xsl:with-param name="pos" select="1"/>
            <xsl:with-param name="sum" select="$elements[1]/@age"/>
        </xsl:call-template>
    </xsl:template>

    <!-- recursive calling template to sum up the ages -->
    <xsl:template name="addthem">
        <xsl:param name="pos"/>
        <xsl:param name="sum"/>

        <xsl:value-of select="$sum"/>
        <xsl:text>
</xsl:text>

        <!-- recursive call to sum up the ages -->
        <xsl:if test="$pos lt number($count)">
            <xsl:call-template name="addthem">
                <xsl:with-param name="pos" select="$pos + 1"/>
                <xsl:with-param name="sum" select="number($sum) + number($elements[$pos + 1]/@age)"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

在您的样本输入上生成以下内容 -

模板（带有标签和内容的原始模板）：

<xsl:stylesheet
        version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="yes" />

    <xsl:variable name="txtlabels" select="tokenize('first,second,third,fourth,fifth,sixth,seventh,eights,ninth,tenth,eleventh,twelveth,thirteenth,fourteenth,fifteenth', ',')"/>

    <!-- Util template to generate labels -->
    <xsl:template name="getlabel">
        <xsl:param name="startat" select="1"/>
        <xsl:param name="idx"/>

        <xsl:if test="number($startat) lt number($idx)">
            <xsl:value-of select="$txtlabels[$startat]"/>
            <xsl:text> </xsl:text>
            <xsl:call-template name="getlabel">
                <xsl:with-param name="startat" select="$startat + 1"/>
                <xsl:with-param name="idx" select="$idx"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>


    <!-- Main Entry point -->
    <xsl:template match="/">
        <xsl:variable name="count">
            <xsl:value-of select="count(/people/man)"/>
        </xsl:variable>

        <xsl:call-template name="addthem">
            <xsl:with-param name="count" select="count(/people/man)"/>
            <xsl:with-param name="pos" select="1"/>
            <xsl:with-param name="sum" select="/people/man[1]/@age"/>
            <xsl:with-param name="elements" select="/people/man"/>
        </xsl:call-template>
    </xsl:template>

    <!-- recursive calling template to sum up the ages -->
    <xsl:template name="addthem">
        <xsl:param name="count"/>
        <xsl:param name="pos"/>
        <xsl:param name="sum"/>
        <xsl:param name="elements"/>

        <!-- get the label prefix, without the 'and' clause -->
        <xsl:variable name="thelabelprefix">
            <xsl:call-template name="getlabel">
                <xsl:with-param name="startat" select="1"/>
                <xsl:with-param name="idx" select="$pos"/>
            </xsl:call-template>
        </xsl:variable>

        <!-- Now append the 'and' clause, if required, to the labels!!! -->
        <xsl:variable name="thelabel">
            <xsl:choose>
                <xsl:when test="number($pos) eq 1">
                    <xsl:value-of select="$txtlabels[$pos]"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of 
select="concat($thelabelprefix, ' and ', $txtlabels[$pos])"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:value-of select="$thelabel"/>
        <xsl:text> : </xsl:text> <xsl:value-of select="$sum"/>
        <xsl:text>

        </xsl:text>

        <!-- recursive call to sum up the ages -->
        <xsl:if test="$pos lt number($count)">
            <xsl:call-template name="addthem">
                <xsl:with-param name="count" select="$count"/>
                <xsl:with-param name="pos" select="$pos + 1"/>
                <xsl:with-param name="sum" select="number($sum) + number($elements[$pos + 1]/@age)"/>
                <xsl:with-param name="elements" select="$elements"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

为您的输入xml生成以下输出：

first : 20
first  and second : 60
first second  and third : 90
first second third  and fourth : 170

我在内部添加了评论，如果您需要进一步的帮助，请与我们联系。它基本上使用两个递归模板，每个模板用于“标签”，另一个用于添加。

而且，您的样本输出应为90和170而不是110和190，或者您的样本输入应该说年龄= 50而不是年龄= 30

Answer 2

以下简短样式表会准确生成您首次要求的输出，包括序数：

<强>样式表：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"
    version="2.0">

<xsl:output method="text"/>

<xsl:template match="/" >
   <xsl:for-each select="people/man">
      <xsl:for-each select=".|preceding-sibling::man">
         <xsl:value-of select="if (position() = last() and last() != 1) 
                               then ' and ' else ' '"/>
         <xsl:number format="w" ordinal="yes"/>
      </xsl:for-each>
      <xsl:text> age </xsl:text>
      <xsl:if test="position() > 1">(combined)</xsl:if>
      <xsl:value-of select="':', sum((.|preceding-sibling::man)/@age), '&#xa;'"/>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

<强>输出：

 first age : 20 
 first and second age (combined): 60 
 first second and third age (combined): 90 
 first second third and fourth age (combined): 170

Answer 3

一个简单的非递归解决方案，适用于兄弟元素的小序列的增量总和：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="man">
  <xsl:value-of select=
    "sum(@age|preceding-sibling::man/@age)"/>
  <xsl:text>&#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档（更正为格式良好）：

<people>
    <man age="20" />
    <man age="40" />
    <man age="30" />
    <man age="80" />
</people>

产生了想要的正确结果：

<强> II。使用scanl 中的FXSL模板/函数，可以为以下大型序列（节点集）提供简单有效的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:myAdd="f:myAdd" xmlns:myParam="f:myParam"
>
  <xsl:import href="scanl.xsl"/>
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <myAdd:myAdd/>

  <myParam:myParam>0</myParam:myParam>

  <xsl:template match="/">

    <xsl:variable name="vFun" select="document('')/*/myAdd:*[1]"/>
    <xsl:variable name="vZero" select="document('')/*/myParam:*[1]"/>


    <xsl:call-template name="scanl">
      <xsl:with-param name="pFun" select="$vFun"/>
      <xsl:with-param name="pQ0" select="$vZero" />
      <xsl:with-param name="pList" select="/*/*/@age"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="myAdd:*" mode="f:FXSL">
    <xsl:param name="pArg1" select="0"/>
    <xsl:param name="pArg2" select="0"/>

    <xsl:value-of select="$pArg1 + $pArg2"/>
  </xsl:template>
</xsl:stylesheet>

开箱即用这个简单的解决方案（只需调用一个模板 - 无需编写递归代码）就可以产生想要的结果：

<el>0</el>
<el>20</el>
<el>60</el>
<el>90</el>
<el>170</el>

xsl sum兄弟值

3 个答案: