Question

我目前正在尝试从标准AS3应用程序和AIR应用程序加载外部SWF文件。似乎AIR应用程序的行为与Flash Player运行的标准SWF的行为方式不同。

根据documentation，applicationDomain的{{1}}属性也可以在AIR应用程序中使用，但它似乎无效。

我有以下代码：

LoaderContext

将此代码编译为SWF文件并使用Flash Player启动它会执行此输出，这似乎是正确的：

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.system.LoaderContext;

    public class Invoker extends Sprite
    {
        private var _ldr : Loader;

        public function Invoker()
        {
            _ldr = new Loader();
            _ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, onChildOneComplete);

            var ldrC : LoaderContext = new LoaderContext(false,
                new ApplicationDomain(ApplicationDomain.currentDomain)
            );

            _ldr.load(new URLRequest("otherSwf.swf"), ldrC);
        }

        private function onChildOneComplete(e : Event) : void
        {
            var c1ad : ApplicationDomain = (e.target as LoaderInfo).applicationDomain;
            var inad : ApplicationDomain = ApplicationDomain.currentDomain;

            trace("Child One parentDomain : " + c1ad.parentDomain);
            trace("Invoker parentDomain   : " + inad.parentDomain);

            trace("Child One has Invoker  : " + c1ad.hasDefinition("Invoker"));
            trace("Invoker has Invoker    : " + inad.hasDefinition("Invoker"));
        }
    }
}

但是与AIR应用程序相同的代码会产生不同的输出：

Child One parentDomain : [object ApplicationDomain]
Invoker parentDomain   : null
Child One has Invoker  : true
Invoker has Invoker    : true

根据文档，第一个输出（使用带有Flash Player的SWF，而不是AIR应用程序）是正确的输出。此外，使用此代码段并将应用程序域更改为其他可能的配置（如Child One parentDomain : null Invoker parentDomain : null Child One has Invoker : false Invoker has Invoker : true或new ApplicationDomain(null)）确实超出了文档对SWF所说的内容，但不会更改AIR的输出应用

任何线索为什么AIR只是忽略传递给加载器上下文的应用程序域？有关此特定问题的任何文档？

非常感谢。

Answer 1

知道了。

问题是由AIR应用程序中SecurityDomain系统中的不同行为引起的。在AIR应用程序中加载SWF文件时，它始终依赖于不同的沙箱。因此，AIR为此SWF创建了一个新的SecurityDomain。

由于SecurityDomain是一个或多个ApplicationDomain的组，此行为会强制创建新的ApplicationDomain（在新SecurityDomain内），忽略指定的一个（属于'main'SecurityDomain）。

使用URLLoader有一种解决方法。从字节码加载（使用Loader.loadBytes）时，SWF将加载到同一SecurityDomain内。这就是为什么你必须将allowLoadBytesCodeExecution设置为true，因为它可能是不安全的。因此，间接加载SWF，首先是URLLoader，然后加载Loader.loadBytes，解决了这个问题。

以下是片段：

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.system.LoaderContext;
    import flash.utils.ByteArray;

    public class Invoker extends Sprite
    {
        public function Invoker()
        {
            var uldr : URLLoader = new URLLoader();
            uldr.dataFormat = URLLoaderDataFormat.BINARY;
            uldr.addEventListener(Event.COMPLETE, onBytesComplete);

            uldr.load(new URLRequest("otherSwf.swf"));
        }

        private function onBytesComplete(e : Event) : void
        {
            var bytes : ByteArray = (e.target as URLLoader).data;

            var ldr : Loader = new Loader();
            ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, onChildComplete);

            var ldrC : LoaderContext = new LoaderContext();

            // This property was for AIR 1.0.
            //ldrC.allowLoadBytesCodeExecution = true;

            // Since AIR 2.0, it's allowCodeImport.
            ldrC.allowCodeImport = true;

            ldr.loadBytes(bytes, ldrC);
        }

        private function onChildComplete(e : Event) : void
        {
            var c1ad : ApplicationDomain = (e.target as LoaderInfo).applicationDomain;
            var inad : ApplicationDomain = ApplicationDomain.currentDomain;

            trace("Child One parentDomain : " + c1ad.parentDomain);
            trace("Invoker parentDomain   : " + inad.parentDomain);

            trace("Child One has Invoker  : " + c1ad.hasDefinition("Invoker"));
            trace("Invoker has Invoker    : " + inad.hasDefinition("Invoker"));
        }
    }
}

希望这有帮助。

Answer 2

这是一个好的，但不是：）

还有一个细节： allowLoadBytesCodeExecution 现在是一个遗留属性，它是在AIR 1.0中定义的。从AIR 2.0开始使用 allowCodeImport 。

侨， PG

LoaderContext和ApplicationDomain是否随Adobe AIR发生变化？

2 个答案: