Question

我正在寻找与Java toString等价的Dhall，因此我可以在其他记录中嵌入一些原始JSON，但我希望确保生成的JSON结构有效。

我有一个记录，例如{ name : Text, age : Natural }并希望将值转换为Text，例如：

let friends = 
[ { name = "Bob", age = 25 }, { name = "Alice", age = 24 }]
in { id = "MyFriends", data = Record/toString friends }

会产生：

{
  "id": "MyFriends, 
  "data": "[ { \"name\": \"Bob\", \"age\": 25 }, { \"name\": \"Alice\", \"age\": 24 }]" 
}

在Dhall中这可能吗？

Answer 1

无法自动派生到JSON的转换，但是您可以使用Prelude对JSON的支持来生成按构造更正的JSON字符串（这意味着它们永远不会格式错误），如下所示：

let Prelude = https://prelude.dhall-lang.org/v13.0.0/package.dhall

let Friend = { name : Text, age : Natural }

let Friend/ToJSON
    : Friend → Prelude.JSON.Type
    =   λ(friend : Friend)
      → Prelude.JSON.object
          ( toMap
              { name = Prelude.JSON.string friend.name
              , age = Prelude.JSON.natural friend.age
              }
          )

let Friends/ToJSON
    : List Friend → Prelude.JSON.Type
    =   λ(friends : List Friend)
      → Prelude.JSON.array
          (Prelude.List.map Friend Prelude.JSON.Type Friend/ToJSON friends)

let friends = [ { name = "Bob", age = 25 }, { name = "Alice", age = 24 } ]

in  { id = "MyFriends", data = Prelude.JSON.render (Friends/ToJSON friends) }

产生以下结果：

{ data =
    "[ { \"age\": 25, \"name\": \"Bob\" }, { \"age\": 24, \"name\": \"Alice\" } ]"
, id = "MyFriends"
}

记录到文本

1 个答案: