Question

如何拼合这样的嵌套列表：

[1, 2, 3, 4] == flatten [[[1,2],[3]],[[4]]]

Answer 1

是的，它来自标准前奏given by

concat

concat :: [[a]] -> [a]
concat xss = foldr (++) [] xss

如果您想将[[[a]]]变为[a]，则必须使用它两次：

Prelude> (concat . concat) [[[1,2],[3]],[[4]]]
[1,2,3,4]

Answer 2

由于没有其他人给出这一点，因此可以定义一个函数，该函数将使用MultiParamTypeClasses展平任意深度的列表。我实际上并没有发现它有用，但希望它可以被认为是一个有趣的黑客。我从Oleg的多变量函数实现中得到了这个想法。

{-# LANGUAGE MultiParamTypeClasses, OverlappingInstances, FlexibleInstances #-}

module Flatten where

class Flatten i o where
  flatten :: [i] -> [o]

instance Flatten a a where
  flatten = id

instance Flatten i o => Flatten [i] o where 
  flatten = concatMap flatten

现在，如果你加载它并在ghci中运行：

*Flatten> let g = [1..5]
*Flatten> flatten g :: [Integer]
[1,2,3,4,5]
*Flatten> let h = [[1,2,3],[4,5]]
*Flatten> flatten h :: [Integer]
[1,2,3,4,5]
*Flatten> let i = [[[1,2],[3]],[],[[4,5],[6]]]
*Flatten> :t i
i :: [[[Integer]]]
*Flatten> flatten i :: [Integer]
[1,2,3,4,5,6]

请注意，通常需要提供结果类型注释，否则ghc无法确定在何处停止递归应用flatten类方法。如果你使用的单态类型的函数就足够了。

*Flatten> :t sum
sum :: Num a => [a] -> a
*Flatten> sum $ flatten g

<interactive>:1:7:
    No instance for (Flatten Integer a0)
      arising from a use of `flatten'
    Possible fix: add an instance declaration for (Flatten Integer a0)
    In the second argument of `($)', namely `flatten g'
    In the expression: sum $ flatten g
    In an equation for `it': it = sum $ flatten g
*Flatten> let sumInt = sum :: [Integer] -> Integer
*Flatten> sumInt $ flatten g
15
*Flatten> sumInt $ flatten h
15

Answer 3

正如其他人所指出的，concat :: [[a]] -> [a]是您正在寻找的功能，它不能展平任意深度的嵌套列表。您需要多次调用它才能将其压缩到所需的水平。

但是，该操作确实可以推广到其他monad。它被称为join，类型为Monad m => m (m a) -> m a。

Prelude Control.Monad> join [[1, 2], [3, 4]]
[1,2,3,4]    
Prelude Control.Monad> join (Just (Just 3))
Just 3
Prelude Control.Monad.Reader> join (+) 21
42

Answer 4

import Data.List
let flatten = intercalate []

flatten $ flatten [[[1,2],[3]],[[4]]]
[1,2,3,4]

Answer 5

正如哈马尔指出的那样，join是压缩列表的“monadic”方式。您也可以使用do - 符号来轻松编写多个级别的平面函数：

flatten xsss = do xss <- xsss
                  xs <- xss
                  x <- xs
                  return x

Answer 6

任意嵌套的列表可以用Data.Tree近似，可以通过适当命名的函数flatten来展平。

我说近似因为Data.Tree允许将数据项附加到每个节点，而不仅仅是叶子。但是，您可以创建Data.Tree (Maybe a)，并将Nothing附加到正文节点，并使用catMaybes . flatten展平。

Answer 7

您可以使用concat删除一级嵌套，因此您可以通过应用concat n次来应用n级嵌套。

不可能编写一个删除任意级别嵌套的函数，因为无法使用Haskell的类型系统表达函数的类型，该函数采用任意嵌套列表并返回平面列表（使用列表数据类型 - 您可以为任意嵌套列表编写自己的数据类型，并为其编写一个flatten函数。）

是否有一个函数来展平嵌套的元素列表？

7 个答案: