VBScript编译错误-预期的子项

Question

我有以下不断收到的脚本

编译错误第16行-预期的子

我看不到是什么原因造成的。

此脚本由 acscript 用于Avaya电话系统。引擎可能会将## cvs_cmd_begin和## cvs_cmd_end替换为其他内容。

'SERVERNAME=123.45.67.89
Public Sub Main()
'## cvs_cmd_begin
' =========================================================
'  ERROR ERROR ERROR
'  If you're having trouble running a script make sure it's Encoding = UTF-8 (use Notepad++)
' =========================================================
'   On Error Resume Next

    SaveFolder = "K:\Telephony\ACD Automation\AutoReport.AgentInterval\Daily 20200124\"
    SaveFile = "Agent.Interval_20200124_12345.txt"

   cvsSrv.Reports.ACD = 1
   Set Info = cvsSrv.Reports.Reports("Historical\Designer\A.Agent Interval")

    If Info Is Nothing Then
        Exit
    Else
        b = cvsSrv.Reports.CreateReport(Info,Rep)

        If b Then
            Rep.TimeZone = "default"    
            Rep.SetProperty "Agent", "12345"
            Rep.SetProperty "Date", "1/24/2020"
            Rep.SetProperty "Times", "07:00-20:45"

            b = Rep.ExportData(SaveFolder & SaveFile, 9, 0, False, True, True)
                Rep.Quit
                Set Rep = Nothing
        End If
    End If

    Set Info = Nothing
'## cvs_cmd_end
End Sub

Answer 1

问题是使用Exit statement而不附带关键字。 Exit语句有五种取决于上下文。

1. Exit Do
2. Exit For
3. Exit Function
4. Exit Sub
5. Exit Property

在这种情况下，如果未设置Info对象变量，则代码将尝试退出子过程。解决方法是将第16行更改为

Exit

到

Exit Sub