Question

我正在为学校创建一个多项选择课程。为此，我必须编写一个xslt样式表来显示正确的答案。

我的XML具有以下结构

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE QUIZ SYSTEM "quiz.dtd">
<?xml-stylesheet type="text/xsl" href="quizanswers.xsl"?>
<quiz>
<multipleChoice solution="3">
    <question>Question 1</question>
    <answer>answer 1</answer>
    <answer>answer 2</answer>
    <answer>answer 3</answer>
    <answer>answer 4</answer>
</multipleChoice>
<multipleChoice solution="4">
    <question>Question 1</question>
    <answer>answer 1</answer>
    <answer>answer 2</answer>
    <answer>answer 3</answer>
    <answer>answer 4</answer>
</multipleChoice>
</quiz>

使用以下xslt文件

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
<body>
<h1>Answers</h1>
<xsl:for-each select="quiz/multipleChoice">
<u><br></br><xsl:value-of select="question"/></u><br></br>
- <xsl:value-of select="question[../multipleChoice/@solution]"/> <br />
</xsl:for-each>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

我想要的是在问题[解决方案的属性]中设置属性解决方案的数量。我取得了哪些成绩但没有成功。有没有人对这个问题提出解决方案/建议？

我也想让这个xml文件有多个样式表......这可能吗？

提前致谢...

Answer 1

是的，您可以使用多个样式表，方法如下：

<xsl:include href="mutiple.xsl"/>

看起来你应该想要答案而不是问题？所以你的XSLT应该像

最终版

在DevNull的有用评论之后，我同意这是最干净的解决方案

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <html>
        <body>
            <h1>Answers</h1>
            <xsl:for-each select="quiz/multipleChoice">
                <u>
                    <br></br>
                    <xsl:value-of select="question"/>
                </u>
                <br></br>
                <br />
                <xsl:value-of select="answer[number(../@solution)]" /><br />
            </xsl:for-each>
        </body>
    </html>
</xsl:template>
</xsl:stylesheet>

Answer 2

试试这个：

<xsl:template match="/">
  <html>
    <body>
      <h1>Answers</h1>
      <xsl:apply-templates />
    </body>
  </html>
</xsl:template>

<xsl:template match="question">
  <u>
    <br />
    <xsl:apply-templates />
  </u>
  <br />
</xsl:template>

<xsl:template match="answer" />

<xsl:template match="answer[position() = ../@solution]">
  <xsl:text>- </xsl:text>
  <xsl:apply-templates />
  <br />
</xsl:template>

最后两个模板忽略所有答案，除非答案节点的位置（仅在答案节点之间）等于其父级的@solution属性。

xslt xpath +多个样式表问题

2 个答案: