Question

我正在尝试检索特定月份内插入的所有行。

SELECT 
    dbo.Post.UserId, 
    dbo.Post.Tags, 
    dbo.Post.CommentCount, 
    dbo.Post.Status,  
    dbo.Post.PostDate, 
    dbo.Post.[Content], 
    dbo.Post.Title, 
    dbo.Post.PostId, 
    dbo.[User].DisplayName 
FROM  
    dbo.Post INNER JOIN
    dbo.[User] ON dbo.Post.UserId = dbo.[User].UserId 
Where PostDate >=  DATEADD(mm, 0, DATEDIFF(mm, 0, '01/28/2009')) 
    AND  PostDate <=  DATEADD(mm, 0, DATEDIFF(mm, 0, '01/28/2009'))

有什么想法吗？

Answer 1

 WHERE PostDate >=  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0)
   AND PostDate <  DATEADD(mm, 1 + DATEDIFF(mm, 0, '01/28/2009'), 0)

Answer 2

你提到“给定月份”，我假设从1到12的月份数。如果你从约会开始，只想要那个月内的所有内容：

@month = datepart(mm, 'given date');
@year  = datepart(yy, 'given date');

Then use:

Where 
   datepart(mm, Post.Postdate) = @month
   and datepart(yy, Post.PostDate) = @year

像那样。

（如果你关心的话，我加了一年。： - ））

Answer 3

您想要创建该月的起始时刻和下个月的起始时刻，然后记录起始时刻的日期，直到但不包括下一个起始时刻。

即。结果应该相当于：

Where PostDate >= '01/01/2009' and PostDate < '02/01/2009'

这将使您完全达到那个月，并且在下个月没有重叠。

表达式DATEDIFF(mm, 0, '2009-01-28')将为您提供01/01/1900的月份数，因此您应该将该日期用作DATEADD中的第三个参数：

DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '01/01/1900')

要获得下个月的开始时刻，您只需使用'02/01/1900'作为偏移。让我们把它放在条件中：

Where
  PostDate >= DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '01/01/1900') and
  PostDate < DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), '02/01/1900')

Answer 4

这样做。

Where PostDate >=  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0) 
    AND  PostDate <  DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009') + 1, 0)

另外，我通常在查询之前设置日期范围，所以我不必将日期函数放在where子句中。

declare @from datetime;
declare @thru datetime;

set @from = DATEADD(mm, DATEDIFF(mm, 0, '01/28/2009'), 0);
set @thru = DATEADD(mm, 1, @from);

...
Where PostDate >=  @from 
        AND  PostDate <  @thru

Answer 5

@dtInput = '01/28/2009'

-- subtract current days (less one) to get to start of month
set @dtStart = dateadd( dd, 1 - datepart( dd, @dtInput ), @dtInput )

-- add a month, then subtract 1 sec to get 23:59:59 on last day of month
set @dtEnd = dateadd( ss, -1, dateadd( mm, 1, @dtStart ))

SELECT ... WHERE PostDate between @dtStart and @dtEnd

如何使用T-Sql在给定月份内检索所有插入的行

5 个答案: