Question

我需要从EXE中提取所有图标并将其保存为磁盘文件，但我无法使用最简单的解决方案（ExtractIconEx），因为我需要以保留大尺寸的方式提取ICO文件图标，即使代码在运行Windows XP的系统上运行。我稍后将使用其他代码提取想要的图标（128x128和其他vista大小图标），但我需要一种方法来提取所有图标，包括所有资源，因为它们存在于EXE中，无论我的代码是否运行PC on正在运行XP，Vista或Win7。

到目前为止，我知道图标位于RT_GROUP_ICONS。

我知道有些人在Delphi之前必须这样做，因为像IcoFX和resource-explorer这样的实用程序似乎已经这样做了。我曾经记得看到一个完全开源的Delphi工具可以做到这一点，但它是在几年前。

重述我使用ExtractIconEx的问题 - 它不会访问整个.ico文件，它只会提取支持的图标资源格式，这是平台支持的单一分辨率（大小）。例如，在XP上，它将提取32x32或48x48图标，但不提取Vista格式的128x128图标。

更新：这是已接受答案的修改版本，可以解决我未来的担忧。如果我们调用的函数以某种方式在未来的Windows版本中从User32.dll中消失，我希望它更优雅地失败，而不是加载我的整个应用程序。

unit ExtractIconUtils;

interface

uses Graphics,Forms,Windows;

//----------------------------------------------------------------------------
// ExtractIcons
// Call "private" MS Api to extract Icon file. This calls a publically
// documented function marked as deprecated in the MSDN documentation.
// It was no doubt Not Originally Intended to be documented, or publically
// accessed, but it provides functionality that its hard to live without.
// It exists on Windows 2000, XP, Vista, and Windows7, but might not exist
// in some future Windows version (released after year 2011).
//
// uses global   hUserDll    : THandle;
//----------------------------------------------------------------------------
function ExtractIcons(exeFilename,icoOutFileName:String;icoSize:Integer):Boolean;



var
  hUserDll    : THandle;





implementation



function ExtractIcons(exeFilename,icoOutFileName:String;icoSize:Integer):Boolean;
const
{$ifdef UNICODE}
 ExtractProcName='PrivateExtractIconsW';
{$else}
 ExtractProcName='PrivateExtractIconsA';
{$endif}
type
  TExtractFunc = function(lpszFile: PChar; nIconIndex, cxIcon, cyIcon: integer; phicon: PHANDLE; piconid: PDWORD; nicon, flags: DWORD): DWORD; stdcall;
var
  hIcon   : THandle;
  nIconId : DWORD;
  Icon    : TIcon;
  PrivateExtractIcons:TExtractFunc;
begin
  result := false;
  if (hUserDll<4) then begin
    hUserDll := LoadLibrary('user32.dll');
    if (hUserDll<4) then exit;
  end;

     { PrivateExtractIcons:
        MSDN documentation says that this function could go away in a future windows
        version, so we must try to load it, and if it fails, return false, rather than
        doing a static DLL import.
     }
    PrivateExtractIcons :=     GetProcAddress(hUserDll, ExtractProcName);

    if not Assigned(PrivateExtractIcons) then exit;

    //extract a icoSize x icoSize  icon where icoSize is one of 256,128,64,48,32,16
    if PrivateExtractIcons ( PWideChar(exeFilename),
                            0, icoSize, icoSize, @hIcon, @nIconId, 1, LR_LOADFROMFILE) <>0 then
    try
      Icon:=TIcon.Create;
      try
        Icon.Handle:=hIcon;
        Icon.SaveToFile(icoOutFileName);
        result := true;
      finally
        Icon.Free;
      end;
    finally
      DestroyIcon (hIcon);
    end;
end ;


initialization
  // none

finalization
   if (hUserDll>4) then
      FreeLibrary(hUserDll);

end.

Answer 1

PrivateExtractIcons功能可以帮助您。您可以指定要提取的图标的大小：

{$IFDEF UNICODE}
    function PrivateExtractIcons(lpszFile: PChar; nIconIndex, cxIcon, cyIcon: integer; phicon: PHANDLE; piconid: PDWORD; nicon, flags: DWORD): DWORD; stdcall ; external 'user32.dll' name 'PrivateExtractIconsW';
{$ELSE}
    function PrivateExtractIcons(lpszFile: PChar; nIconIndex, cxIcon, cyIcon: integer; phicon: PHANDLE; piconid: PDWORD; nicon, flags: DWORD): DWORD; stdcall ; external 'user32.dll' name 'PrivateExtractIconsA';
{$ENDIF}

procedure TMainForm.Button1Click(Sender: TObject);
var
    hIcon   : THandle;
    nIconId : DWORD;
    Icon    : TIcon;
begin
    //Extract a 128x128 icon
    if PrivateExtractIcons ('C:\Users\Public\Documents\RAD Studio\Projects\2010\Aero Colorizer\AeroColorizer.exe', 0, 128, 128, @hIcon, @nIconId, 1, LR_LOADFROMFILE) <>0 then
    try
        Icon:=TIcon.Create;
        try
            Icon.Handle:=hIcon;
            Icon.SaveToFile(ExtractFilePath(ParamStr(0))+'Aicon.ico');
        finally
            Icon.Free;
        end;
    finally
        DestroyIcon (hIcon);
    end;
end ;

Answer 2

这是working example on Delphi Praxis。它读取指定可执行文件的默认RT_GROUP_ICON和关联的RT_ICON资源，并将它们保存为完整的多图像.ICO文件。

似乎被256像素图像混淆了（保存格式无效），至少在XP上，所以可能需要稍微调整一下。

不使用ExtractIconEx从EXE中提取所有图标

2 个答案: