Question

为Unity写一个着色器，我不明白这里发生了什么。我有一个附有材料的球体。材质已附加着色器。着色器非常简单，它会生成一些单纯形噪声，然后将其用作球体的颜色。

着色器代码：

Shader "SimplexTest"
{
    Properties
    {
      _SimplexScale("Simplex Scale", Vector) = (4.0,4.0,4.0,1.0)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue"="Geometry" }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "SimplexNoise3D.hlsl"

            float3 _SimplexScale;

            struct appdata
            {
                float4 vertex : POSITION;
            };

            struct v2f
            {
                float4 position : SV_POSITION;
                float4 color : COLOR0;
            };

            v2f vert (appdata v)
            {
                v2f o;
                float4 worldPosition = mul(unity_ObjectToWorld, v.vertex);
                o.position = UnityObjectToClipPos(v.vertex);

                float small = snoise(_SimplexScale * worldPosition);
                // o.color = small * 10; // Non-Saturated (A) Version
                o.color = saturate(small * 10); // Saturated (B) Version

                return o;
            }


            fixed4 frag (v2f i) : SV_Target
            {
                return i.color;
            }
            ENDCG
        }
    }
}

单纯形噪声函数来自Keijiro's Github。

非饱和（A）版本：

饱和（B）版本：

非饱和版本（版本A）符合预期。通过将单纯形噪声乘以10，可以得到一系列的白色和黑色斑点。理论上，饱和（B版）应该将所有白色斑点从1处切掉，将黑色斑点从0处切掉。但是它似乎正在创建一个全新的渐变，我不知道为什么。

我假设我缺少一些关键假设，但由于数学似乎正确，我不清楚那会是什么。

Answer 1

在灰色区域中，片段着色器的像素介于颜色0和1的顶点之间。这意味着输入将在这些值之间进行插值，从而创建灰色i.color值。

一种解决方法是首先，将您的网格更改为每个三角形具有单独的顶点，以便每个三角形可以拥有所有具有相同法线的顶点。

然后，一旦每个三角形的所有顶点共享相同的法线，您就可以基于顶点着色器中的SV_NORMAL值来制作颜色，而无需进行变换POSITION值。

类似的东西：

struct appdata
{
    float4 vertex : POSITION;
    float4 normal : NORMAL;
};

...

v2f vert (appdata v)
{
    v2f o;
    float3 worldNormal = UnityObjectToWorldNormal(v.normal);
    o.position = UnityObjectToClipPos(v.vertex);

    float small = snoise(_SimplexScale * worldNormal);
    o.color = saturate(small * 10);

    return o;
}

然后，它应该会按预期工作。

可以帮助完成这项工作的另一种方法（如果要在版本A中保留一点插值）是让插值继续进行，但是只需在片段着色器中进行饱和：

v2f vert (appdata v)
{
    v2f o;
    float4 worldPosition = mul(unity_ObjectToWorld, v.vertex);
    o.position = UnityObjectToClipPos(v.vertex);

    float small = snoise(_SimplexScale * worldPosition);
    o.color = small * 10;

    return o;
}


fixed4 frag (v2f i) : SV_Target
{
    return saturate(i.color);
}

在示例A中不会在很大程度上发生问题的原因是它是在小于或等于零的值与较大的正数之间进行插值。而且由于在非常大的数字和零附近的数字之间插值的东西通常会大于1，所以您会得到很多呈现为白色的像素。

着色器saturate（）在不应该创建渐变的情况下

1 个答案: