Question

我是Erlang的新手，正在尝试编写一个程序，该程序将像[1,5,4,5,3,2,2,2,8,11]这样的数字列表作为函数的输入参数。该函数应返回一个元组列表，其中记录了该数字及其在列表中的出现次数，如下所示。

[{1,1}，{2,2}，{3,1}，{4,1}，{5,1}，{8,1}，{11,1}]。

我有以下代码

list([]) ->
  [];
list([First | Rest])  ->  
  [{First,+1} | list(Rest)].

但是我不知道我可以进行计数操作吗？谢谢

Answer 1

可能不是最快的（如果考虑速度，请使用地图而不是元组列表）：

count([]) ->
    [];
count([H|T]) ->
    count2([H|T], []).

count2([H|T], L) ->
    case lists:keyfind(H, 1, L) of
        {H, X} ->
            L2 = lists:append(lists:delete({H, X}, L), [{H,X+1}]) ;
        false ->
            L2 = lists:append(L, [{H, 1}])
    end,
    count2(T, L2);
count2([], L) ->
    L.

使用地图，代码会更简单：

count([]) ->
    #{};
count(L) ->
    count2(L, #{}).

count2([H|T], M) ->
    Y = case maps:is_key(H, M) of
            true  -> #{H := X} = M,
                     X + 1;
            false -> 1
        end,
    count2(T, M#{H => Y});
count2([], M) ->
    M.

Answer 2

请参见maps:update_with/4：

frequencies(List) ->
    frequencies(List, #{}).

frequencies([], Freqs) ->
    maps:to_list(Freqs);
frequencies([H|T], Freqs) ->
    Incrementer = fun(Count) -> Count+1 end,
    NewFreqs = maps:update_with(H, Incrementer, _Default=1, Freqs),
    frequencies(T, NewFreqs).

在外壳中：

1> a:frequencies([1,5,4,5,3,2,2,8,11]).
[{1,1},{2,2},{3,1},{4,1},{5,2},{8,1},{11,1}]

您介意逐步解释此代码的工作原理

此部分：

frequencies(List) ->
    frequencies(List, #{}).

让我们通过仅传递一个列表来调用frequencies/1函数。然后，该列表连同一个空映射被中继到frequencies/2函数以存储结果。

此部分：

frequencies([H|T], Freqs) ->
    Incrementer = fun(Count) -> Count+1 end,
    NewFreqs = maps:update_with(H, Incrementer, _Default=1, Freqs),
    frequencies(T, NewFreqs).

使用模式匹配从列表H中删除第一个数字，然后调用传递第一个数字作为应在映射中更新的Key的函数maps:update_with/4。 maps:update_with/4的其他自变量是要更新的映射Freqs和函数Incrementer，该函数接收与映射中的Key关联的值作为自变量。 Incrementer函数的返回值是应该为映射中的Key插入的新值。如果映射中不存在该密钥，则将新的密钥与_Default值一起输入到映射中。

maps:update_with/4返回更新的映射NewFreqs，该映射作为参数传递给递归函数调用：

frequencies(T, NewFreqs).

第一个参数T是包含剩余数字的列表。删除列表中的所有数字后，递归函数调用将为：

frequencies([], #{ results in this map })

该函数调用将与此函数子句匹配：

frequencies([], Freqs) ->
    maps:to_list(Freqs);

和maps:to_list/1将映射转换为{Key, Value}元组的列表。因为该函数子句的主体中没有递归函数调用，所以递归结束，并返回元组列表。

也许不同的变量名将使代码更易于遵循：

frequencies(List) ->
    frequencies(List, _ResultsMap=#{}).

frequencies([Key|Keys], ResultsMap) ->
    Incrementer = fun(Value) -> Value+1 end,
    NewResultsMap = maps:update_with(Key, Incrementer, _Default=1, ResultsMap),
    frequencies(Keys, NewResultsMap);
frequencies([], ResultsMap) ->
    maps:to_list(ResultsMap).

Answer 3

您可以将它作为一个单行代码来完成，但是将其分解为以下步骤：

List  = [1,5,4,5,3,2,2,8,11].
Keys  = lists:usort(List).
Count = fun(V,L) -> length(lists:filter(fun(E) -> E == V end, L)) end.

> lists:map(fun(K) -> { K, Count(K,List) } end, Keys).

结果：

[{1,1},{2,2},{3,1},{4,1},{5,2},{8,1},{11,1}]

Erlang，查找列表中数字出现的次数

3 个答案: