Question

我正在使用DrRacket。

我该如何使用累加器和相互递归的函数编写一个函数以求出列表中最大和最小值之间的差。

例如，（列表10 2 3 -5 4 1 -6））9）。该列表在列表中至少有一个元素。

我需要两个蓄电池吗？

Answer 1

版本1 ：基于累加器的解决方案，是相互递归的。由于假定输入列表为非空，因此我们从第一个元素为max和min开始。浏览列表时，我们通过将当前元素与累加器进行比较来选择新的最大值和最小值。

#lang racket

; [NEList-of Number] -> Number
(define (max-min-diff.v1 nelst)
  (max-min-diff/t.v1 (rest nelst) (first nelst) (first nelst)))

; [List-of Number] -> Number
(define (max-min-diff/t.v1 l max min)
  (cond [(empty? l) (- max min)]
        [else (get-new-max-min (rest l) (first l) max min)]))

; [List-of Number] Number Number Number -> Number
(define (get-new-max-min rst fst max min)
  (max-min-diff/t.v1 rst
                  (if (> fst max) fst max)
                  (if (< fst min) fst min)))


(max-min-diff.v1 '(0 33 2 32 4 8 3 3 5))
; => 33

(max-min-diff.v1'(1 3 9 4 7 2 2 5 11))
; => 10

版本2 ：基于累加器的解决方案，不能相互递归。更抽象，因为我们将比较器传递给通用帮助器。

; [NEList-of Number] -> Number
(define (max-min-diff.v2 nelst)
  (max-min-diff/t.v2 (rest nelst) (first nelst) (first nelst)))

; [List-of Number] -> Number
(define (max-min-diff/t.v2 l max min)
  (cond [(empty? l) (- max min)]
        [else (max-min-diff/t.v2 (rest l)
                                (f-if (first l) max >)
                                (f-if (first l) min <))]))

; X X [X X -> Boolean] -> X
(define (f-if n1 n2 func)
  (if (func n1 n2) n1 n2))



(max-min-diff.v2 (list 0 33 2 32 4 8 3 3 5))
; => 33

(max-min-diff.v2 (list 1 3 9 4 7 2 2 5 11))
; => 10

版本3 ：小版本。没有明确的递归。

(define (max-min-diff.v3 nelst)
  (- (apply max nelst) (apply min nelst)))

(max-min-diff.v3 (list 0 33 2 32 4 8 3 3 5))
; => 33

(max-min-diff.v3 (list 1 3 9 4 7 2 2 5 11))
; => 10

列表中的最大和最小数字

1 个答案: