Question

我正在尝试从book学习Liquid Haskell。为了检验我的理解，我想编写一个函数log2，该函数采用2 ^ n形式的输入并输出n。

我有以下代码：

powers :: [Int]
powers = map (2^) [0..]

{-@ type Powers = {v:Nat | v elem powers } @-}
{-@ log2 :: Powers -> Nat @-}
log2 :: Int -> Int
log2 n
 | n == 1 = 0
 | otherwise = 1 + log2 (div n 2)

但是在执行此代码时会发生一些奇怪的错误，即“优化中的排序错误”。我无法理解并解决此错误。

任何帮助将不胜感激。

编辑：来自Liquid Haskell书：

谓词是原子谓词，可以通过比较获得两个表达式，或者将谓词函数应用于列表争论...

在Liquid Haskell逻辑语法中，允许的谓词之一是：e r e，其中r是原子二进制关系（并且功能只是特殊的一种关系）。

此外，在本教程中，他们将Even子类型定义为： {-@ type Even = {v:Int | v mod 2 == 0 } @-}

基于此，我认为elem应该有效。

但是现在，正如@ ThomasM.DuBuisson指出的那样，我考虑改为编写自己的elem'，以避免造成混乱。

elem' :: Int -> [Int] -> Bool
elem' _ [] = False
elem' e (x:xs)
 | e==x = True
 | otherwise = elem' e xs

据我所知，现在能够将此elem'用作谓词功能，我需要将其作为度量。因此，我添加了以下内容：

{-@ measure elem' :: Int -> [Int] -> Bool @-}

现在，我在elem的类型定义中将elem'替换为Powers。但是我仍然遇到与上一个相同的错误。

Answer 1

@TomMD是指“反射”的概念，它使您可以将Haskell函数（在某些限制下）转换为精化形式，例如看到这些帖子：

https://ucsd-progsys.github.io/liquidhaskell-blog/tags/reflection.html

不幸的是，尚未使用此材料更新本教程。

因此，例如，您可以如下所示描述log2 / pow2：

https://ucsd-progsys.github.io/liquidhaskell-blog/tags/reflection.html

http://goto.ucsd.edu/liquid/index.html#?demo=permalink%2F1573673688_378.hs

特别是您可以写：

{-@ reflect log2 @-}
log2 :: Int -> Int
log2 1 = 0
log2 n = 1 + log2 (div n 2) 

{-@ reflect pow2 @-}
{-@ pow2 :: Nat -> Nat @-}
pow2 :: Int -> Int
pow2 0 = 1
pow2 n = 2 * pow2 (n-1)

然后您可以在编译时“检查”以下各项是否正确：

test8 :: () -> Int
test8 _ = log2 8 === 3

test16 :: () -> Int
test16 _ = log2 16 === 4

test3 :: () -> Int
test3 _ = pow2 3 === 8

test4 :: () -> Int
test4 _ = pow2 4 === 16

但是，类型检查器将拒绝以下内容

test8' :: () -> Int
test8' _ = log2 8 === 5     -- type error

最后，您可以证明有关log2和pow2的以下定理

{-@ thm_log_pow :: n:Nat -> { log2 (pow2 n) == n } @-}

“证明”是通过“ n上的归纳法”表示的，

thm_log_pow :: Int -> () 
thm_log_pow 0 = ()
thm_log_pow n = thm_log_pow (n-1)

回到原始问题，您可以将isPow2定义为：

{-@ reflect isEven @-}
isEven :: Int -> Bool
isEven n = n `mod` 2 == 0

{-@ reflect isPow2 @-}
isPow2 :: Int -> Bool
isPow2 1 = True
isPow2 n = isEven n && isPow2 (n `div` 2)

您可以通过验证以下内容来“测试”它是否正确：

testPow2_8 :: () -> Bool
testPow2_8 () = isPow2 8 === True 

testPow2_9 :: () -> Bool
testPow2_9 () = isPow2 9 === False

最后，通过为pow2提供精确类型：

{-@ reflect pow2 @-}
{-@ pow2 :: Nat -> {v:Nat | isPow2 v} @-}
pow2 :: Int -> Int
pow2 0 = 1
pow2 n = 2 * pow2 (n-1)

希望这会有所帮助！

如何在Liquid Haskell中编写log2函数

1 个答案: