Question

是否可以在vim中索引纯文本文件（书籍），例如：

1. This line contains the words : London, Berlin, Paris
2. In this line, I write about : New-York, London, Berlin
...
100. And, to conclude, my last comments about : New-York, Paris

并得到这个结果索引：

Berlin : 1
London : 1, 2
New-York : 2, ..., 100
Paris : 1, ..., 100

并且，如果可能，标记方法是什么？我已经读过有关ctags的内容，但它似乎专注于特定的语言（并说实话，对我的需求有点过分）

Answer 1

我冒昧地编写了以下函数，基于使用:g/STRING/#命令来获取匹配项。我将此命令的结果读入列表，然后处理它以返回匹配行号的列表：

function! IndexByWord( this_word )
    redir => result
    sil! exe ':g/' . a:this_word . '/#'
    redir END
    let tmp_list = split(strtrans(result),"\\^\@ *")
    let res_list = []
    call map(tmp_list, 'add(res_list,matchstr(v:val,"^[0-9]*"))')
    let res = a:this_word . ' : ' . string(res_list)
    let res = substitute(res, "[\\[\\]\\']", "", "g")
    echo res
endfunction

因此，您可以在所有单词上调用此函数（或编写脚本来执行此操作）并将输出定向到文件。也许并不是很优雅，但是非常自足。

希望这有助于而不是阻碍。

Answer 2

以下是Prince Goulash发布的功能的修订版。此版本将单词列表作为输入，并返回结果的格式化和按字母顺序排列的字符串：

function! IndexByWord( wordlist )
    let temp_dict = {}
    for word in a:wordlist
        redir => result
        sil! exe ':g/' . word . '/#'
        redir END
        let tmp_list = split(strtrans(result),"\\^\@ *")
        let res_list = []
        call map(tmp_list, 'add(res_list,str2nr(matchstr(v:val,"^[0-9]*")))')
        let temp_dict[word]  = res_list
    endfor
    let result_list = []
    for key in sort(keys(temp_dict))
        call add(result_list, key . ' : ' . string(temp_dict[key])[1:-2])
    endfor
    return join(result_list, "\n")
endfunction

调用它的一种方法是：

echo IndexByWord(['word1', 'word2', 'word3', etc])

拥有一长串单词应该没有问题，尽管在这种情况下你可能想要使用一个列表变量，结果当然会花费更多时间。例如：

let my_word_list = ['word1', 'word2', . . . 'word1000']
echo IndexByWord(my_word_list)

Answer 3

看看ptx，也许是

:%!cut -d: -f2 | ptx -Ar

未修改时会输出这样的内容：

:1:                         London,   Berlin, Paris
:2:               New-York, London,   Berlin
:1:                                   London, Berlin, Paris
:2:                       New-York,   London, Berlin
:2:                                   New-York, London, Berlin
:4:                                   New-York, Paris
:1:                 London, Berlin,   Paris
:4:                       New-York,   Paris
:2:                            New-   York, London, Berlin
:4:                            New-   York, Paris

我会看看我是否可以完成剩下的步骤

Vim：如何索引纯文本文件？

3 个答案: