Question

我有一个TPair个记录的通用数组，其中包含一个整数索引和一个双精度值。我通过构造一个仅TPair的值调用默认TComparer<TPair<Integer, Double>>的{{1}}来按每个TComparer<Double>的值对该数组进行排序。但是，我在调用排序时遇到访问冲突。问题似乎与以下事实有关：我的一些价值观是TPair。我无法控制某些值将为NaN的事实，因此我需要解决这个问题。

在尝试调用默认的NaN进行双打之前，我尝试检查NaN是否为TComparer，而用NaN替换了Low(Integer)，但这没有帮助。至此，我已经完成了一个测试应用程序，该程序可以重现该问题，并且可以看到TArray.QuickSort函数正在对包含3个项目的数组执行数千次比较...不确定发生了什么。

打印出每次调用中两个自定义比较器所比较的两对，结果如下：

[0] Left = (0, 1.00); Right = (1, NAN)
[1] Left = (1, NAN); Right = (1, NAN)
[2] Left = (2, 3.00); Right = (1, NAN)
[3] Left = (0, 0.00); Right = (1, NAN)
[4] Left = (0, 0.00); Right = (1, NAN)
...
[7328] Left = (0, 0.00); Right = (1, NAN)
[7329] Left = (58976, 0.00); Right = (1, NAN)

在写出最后一行后，对我的比较器的后续调用会发生访问冲突。

这是一个完整的测试应用程序：

program Project51;

{$APPTYPE CONSOLE}

{$R *.res}

uses
   System.SysUtils, Generics.Collections, Generics.Defaults, Math;

type
   TIntDblPair = TPair<Integer, Double>;

var
   Comparer1, Comparer2 : IComparer<TIntDblPair>;
   ResultSet : TArray<TIntDblPair>;
   nCompares : Integer;

procedure Test(AComparer : IComparer<TIntDblPair>);
var
   I : Integer;
begin
   TArray.Sort<TIntDblPair>(ResultSet, AComparer);
   for I := 0 to Length(ResultSet) - 1 do
      WriteLn(Format('%d: %f', [ResultSet[I].Key, ResultSet[I].Value]));
   WriteLn;
end;

begin
   try
      SetLength(ResultSet, 3);
      ResultSet[0] := TIntDblPair.Create(0, 1);
      ResultSet[1] := TIntDblPair.Create(1, NaN);
      ResultSet[2] := TIntDblPair.Create(2, 3);

      nCompares := 0;
      Comparer1 := TComparer<TIntDblPair>.Construct(
                     function(const Left, Right: TIntDblPair): Integer
                     begin
                        WriteLn(Format('[%d] Left = (%d, %f); Right = (%d, %f)', [nCompares, Left.Key, Left.Value, Right.Key, Right.Value]));
                        Result := TComparer<Double>.Default.Compare(Right.Value, Left.Value);
                        Inc(nCompares);
                     end
                   );
//      Test(Comparer1);

      nCompares := 0;
      Comparer2 := TComparer<TIntDblPair>.Construct(
                     function(const Left, Right: TIntDblPair): Integer
                     begin
                        WriteLn(Format('[%d] Left = (%d, %f); Right = (%d, %f)', [nCompares, Left.Key, Left.Value, Right.Key, Right.Value]));
                        if IsNaN(Right.Value) then
                           Result := TComparer<Double>.Default.Compare(Low(Integer), Left.Value)
                        else if IsNaN(Left.Value) then
                           Result := TComparer<Double>.Default.Compare(Right.Value, Low(Integer))
                        else
                           Result := TComparer<Double>.Default.Compare(Right.Value, Left.Value);
                        Inc(nCompares);
                     end
                   );
      Test(Comparer2);

      Readln;
   except
      on E: Exception do
         Writeln(E.ClassName, ': ', E.Message);
   end;
end.

Remy LeBeau指出我在Comparer2中的检查未完成。用以下内容替换Comparer2可使该排序调用返回预期的输出。因此，显然问题出在默认的双重比较器尝试比较NaN的时候。比较器实现是一个错误吗？

Comparer2 := TComparer<TIntDblPair>.Construct(
               function(const Left, Right: TIntDblPair): Integer
               begin
                  if IsNaN(Right.Value) and IsNaN(Left.Value) then
                     Result := 0
                  else if IsNaN(Right.Value) then
                     Result := TComparer<Double>.Default.Compare(Low(Integer), Left.Value)
                  else if IsNaN(Left.Value) then
                     Result := TComparer<Double>.Default.Compare(Right.Value, Low(Integer))
                  else
                     Result := TComparer<Double>.Default.Compare(Right.Value, Left.Value);
               end
             );

Answer 1

排序完成后，NaN的位置是在数组的正面还是背面？当您检测到NaN时，根本不要调用默认的TComparer，只需返回< 0或> 0即可，具体取决于您希望NaN定位在哪个位置设置为另一个值（如果两者均为NaN，则返回0）。并且当您为两个非TComparer值调用默认的NaN时，您在Left.Value和Right.Value中都向后倒退了Compare1和Compare2

尝试这样的方法：

Comparer2 := TComparer<TIntDblPair>.Construct(
               function(const Left, Right: TIntDblPair): Integer
               begin
                 if IsNaN(Left.Value) then begin
                   if IsNaN(Right.Value) then begin
                     Result := 0;
                     // or maybe:
                     // Result := TComparer<Integer>.Default.Compare(Left.Key, Right.Key);
                   end else begin
                     // To move Nan's to the front of the array, return -1 here
                     // To move Nan's to the back of the array, return 1 here
                     Result := ...;
                   end;
                 end
                 else if IsNaN(Right.Value) then begin
                   // To move Nan's to the front of the array, return 1 here
                   // To move Nan's to the back of the array, return -1 here
                   Result := ...;
                 end else begin
                   Result := TComparer<Double>.Default.Compare(Left.Value, Right.Value);
                   // and maybe:
                   // if Result = 0 then
                   //   Result := TComparer<Integer>.Default.Compare(Left.Key, Right.Key);
                 end;
               end
             );

当某些值为NaN时，为什么我的TArray <TPair <Integer，Double >>无法使用自定义比较器排序？

1 个答案: