Question

让我们假设有一个祖父母的清单，其中每个人都有孩子，并且递归地每个人都有自己的孩子。像一棵家谱。

比方说，祖父母之一是Aerys Targaryen。

Aerys Targaryen 有3个孩子，Rheagar，Viserys和Daenerys。

Rhaegar 有1个孩子，John Snow。

Viserys 有0个孩子。

Daenerys 有3个孩子，分别是Drogon，Rhealgal和Viserion。

我想制作一张表格，显示：

第一列：祖父母的姓名

第二列：祖父母拥有的孩子数（第一列）

第三列：孩子的名字

第四列：父母拥有的孩子数（第三列）

第五列：孩子的名字

我想要这样的结果：

+-----------------+--------+----------+--------+-----------+
|     GPName      | PCount |  PName   | CCount |   CName   |
+-----------------+--------+----------+--------+-----------+
| Aerys Targaryen |      3 | Rhaegar  |      1 | John Snow |
| Aerys Targaryen |      3 | Viserys  |      0 |           |
| Aerys Targaryen |      3 | Daenerys |      3 | Drogon    |
| Aerys Targaryen |      3 | Daenerys |      3 | Rhaegal   |
| Aerys Targaryen |      3 | Daenerys |      3 | Viserion  |
+-----------------+--------+----------+--------+-----------+

我已经设法进行了这些查询，但我所想要的都不是。

1。

SELECT ?GPName (count(?PName) as ?number)(group_concat(?PName;separator=",") as ?PName)
WHERE
{
     ?gp rdf:type gag:GrandParent .
     ?gp gag:name ?GPName .
     ?p gag:has_parent ?gp .
     ?p rdf:type gag:Parent .
     ?p gag:name ?PName
} group by ?GPName

我只获得前三列，而不是我想要的形式。

2。

SELECT ?GPName 
       (count(?PName) as ?PCount)
       ?PName
       (count(?CName) as ?CCount)
WHERE
{
      ?gp rdf:type gag:GrandParent .
      ?gp gag:name ?GPName .
      ?p rdf:type gag:Parent .
      ?p gag:name ?PName.
      ?p gag:has_parent ?gp .
      ?c rdf:type gag:Child .
      ?c gag:name ?CName.
      ?c gag:has_parent ?p.
} GROUP BY ?GPName ?PName

它只显示第1、3、4列。

Answer 1

如前所述，您需要两个单独的子查询来计算每个解决方案所需的聚合。在没有父代子代的情况下添加了OPTIONAL，并在投影中使用了coalesce表达式将其设置为零。

例如以下查询内容（我已将其与http://geo.linkedopendata.gr/gag-endpoint上的数据集进行了比较）：

PREFIX gag: <http://geo.linkedopendata.gr/gag/ontology/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select ?gpName ?cnt ?PName (coalesce(?cc, 0) as ?cnt2) ?CName
WHERE 
{
    {
        select ?gp (count(?pe1) as ?cnt) {
            ?gp a gag:Περιφέρεια .
            ?pe1 a gag:Περιφερειακή_Ενότητα  .
            ?pe1 gag:ανήκει_σε ?gp .
        }group by ?gp 
    }
    ?gp gag:έχει_επίσημο_όνομα ?gpName .
    ?pe a gag:Περιφερειακή_Ενότητα  .
    ?pe gag:ανήκει_σε ?gp .
    ?pe gag:έχει_επίσημο_όνομα ?PName .
    optional {
        ?c rdf:type gag:Δήμος .
        ?c gag:έχει_επίσημο_όνομα ?CName.
        ?c gag:ανήκει_σε ?pe .
        {
            select ?pe (count(?c1) as ?cc) {
                ?c1 rdf:type gag:Δήμος .
                ?c1 gag:ανήκει_σε ?pe .
            } group by ?pe
        }
    }
}

p.s。作为子查询的替代方法，您可以为子代和孙代创建笛卡尔乘积，并计算不同的绑定，例如：

PREFIX gag: <http://geo.linkedopendata.gr/gag/ontology/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
select ?gpName ?PName ?CName (count(distinct ?p1) as ?cnt1) (count(distinct ?c1) as ?cnt2) 
    WHERE 
    {
        ?gp a gag:Περιφέρεια .
        ?gp gag:έχει_επίσημο_όνομα ?gpName .
        ?pe gag:ανήκει_σε ?gp .
        ?pe a gag:Περιφερειακή_Ενότητα  .
        ?pe gag:έχει_επίσημο_όνομα ?PName .
        ?p1 gag:ανήκει_σε ?gp . # cartesian product with ?pe and ?p1
        ?c gag:ανήκει_σε ?pe .
        ?c gag:έχει_επίσημο_όνομα ?CName .
        ?c1 gag:ανήκει_σε ?pe . # cartesian product with ?c and ?c1

    } group by ?gpName ?PName ?CName
    order by ?gpName ?PName

计算孩子的数量以及这些孩子的孩子

1 个答案: