Question

我正在编写AppleScript来处理一些MTS文件。该脚本以递归方式遍历顶级文件夹“ Volumes：G-Drive：video”的子文件夹。子文件夹被安排到Year文件夹中，从2005年的名为“ 2005”的文件夹开始。运行时错误与脚本尝试迭代的第一个文件夹“ 2005”一起发生。我怀疑这与我处理别名和文本的方式有关，但是在这一点上我很困惑如何解决它。运行时错误是这样的：无法将{alias“ G-DRIVE：video：”，“ 2005：”}设置为整数类型。

我不知道整数在我的代码中出现的位置，以便得到此错误。脚本编辑器没有将我指向代码中运行时错误的位置，因此我也不知道如何找出导致此错误的行。

set folderName to "Volumes:G-Drive:video" as alias

my processFolder("", folderName)

on processFolder(root, folderNameToProcess)
    tell application "Finder"
        set theItems to every file of folder (root & folderNameToProcess)
        repeat with theFile in theItems
            set Nm to name of theFile as text
            set Ex to name extension of theFile
            if Nm does not contain "-c" and Ex is "MTS" then
                set NmMinusExt to my remove_extension(Nm)
                set logMsg to "Deleting " & Nm
                my logThis(logMsg)
                tell application "Finder" to delete theFile
            end if
        end repeat
        set theItems to every file of folder (root & folderNameToProcess)
        repeat with theFile in theItems
            set Nm to name of theFile as text
            set Ex to name extension of theFile
            --tell (info for theFile) to set {Nm, Ex} to {name, name extension}
            if Nm contains "-c" and Ex is "MTS" then
                set NmMinusExt to my remove_extension(Nm)
                set shortNm to my remove_lastTwoCharacters(NmMinusExt)
                set name of theFile to shortNm & ".MTS" as text
                set logMsg to "Renaming " & Nm
                my logThis(logMsg)
                --set lastTwoLetters to characters (((length of Nm) - 2) as number) thru (((length of Nm) - 0) as number) of (Nm as text)
                --if lastTwoLetters is "-c" then
                --display notification lastTwoLetters
                --end if
            end if
        end repeat
        set theFolders to name of folders of folder (root & folderNameToProcess)
        repeat with theFolder in theFolders
            copy theFolder as string to TheFolderName
            display notification "found folder named: " & TheFolderName
            set firstChar to (text 1 thru 1 of TheFolderName)
            if firstChar is not "." then
                --display dialog (folderNameToProcess & TheFolderName & ":")
                try
                    my processFolder(folderNameToProcess, TheFolderName & ":")
                on error errStr number errorNumber
                    display dialog errStr
                end try
            end if
        end repeat
    end tell
    return
end processFolder

on remove_extension(this_name)
    if this_name contains "." then
        set this_name to ¬
            (the reverse of every character of this_name) as string
        set x to the offset of "." in this_name
        set this_name to (text (x + 1) thru -1 of this_name)
        set this_name to (the reverse of every character of this_name) as string
    end if
    return this_name
end remove_extension

on remove_lastTwoCharacters(this_name)
    set this_name to ¬
        (the reverse of every character of this_name) as string
    set this_name to (text 3 thru -1 of this_name)
    set this_name to (the reverse of every character of this_name) as string
    return this_name
end remove_lastTwoCharacters

“脚本编辑器”的“事件”窗格产生以下跟踪：

tell application "Finder"
    get every file of folder "G-DRIVE:video:"
    get every file of folder "G-DRIVE:video:"
    get name of every folder of folder "G-DRIVE:video:"
    display notification "found folder named: 2005"
end tell
tell application "Script Editor"
    display notification "found folder named: 2005"
end tell
tell application "Finder"
    get every file of folder {alias "G-DRIVE:video:", "2005:"}
    display dialog "Finder got an error: Can’t make {alias \"G-DRIVE:video:\", \"2005:\"} into type integer."

Answer 1

folderName是别名。尝试将别名和字符串连接起来会创建一个错误指示的列表。

解决方案是仅使用（HFS）字符串路径。

替换

set folderName to "Volumes:G-Drive:video" as alias

使用

set folderName to "G-Drive:video:"

尾部冒号对于添加路径组成部分至关重要

Applescript错误：无法将{alias“ G-DRIVE：video：”，“ 2005：”}设置为整数类型

1 个答案: