Question

我有一些我已经在Fortran 95中编程的有限元代码，这些代码已经过优化，因此现在可以达到16Mil以上。元素在2GB的内存占用下工作。

我的代码的源函数不平滑，所以我使用的是（分层的）蒙特卡洛方法，该方法需要一个随机数生成器来选择样本位置

我尝试使用-fopenmp -Ofast -ftree-parallelize-loops=4使用gfortran-9进行编译，但是带有随机数生成器的循环不会并行进行。我尝试了do concurrent，但显然没有用，因为random_number并不是“纯”的。 https://stackoverflow.com/a/32637737/2372254 我也尝试阻止我的循环，但是那也不起作用。

这是我在说的代码

        do  k=1,n_els ! total elements is n_els**2. This is block
            do i=1+ (k-1)*n_els ,k*n_els
                supp_vec = 0 
                integ_vec = 0.0_wp

                ! in this subroutine I call random_number
                call do_element(ind, n_els, i, num_points_per_strat, &
                                strat_rows, strat_cols, supp_vec, integ_vec) 
                do j=1, 4
                    sc_vec(supp_vec(j) ) = integ_vec(j)
                end do
                ! give some info about progress

                if (mod( i , (n_els**2)/10) == 0) print*, i*10/((n_els**2)/10), "% done"
            end do
        end do

似乎我可以将块写入文件并调用n该例程的不同实例。我认为必须有一种更清洁的方法。关于如何更快地进行操作的任何提示？

我当时正在考虑先将一个块价值的点（取决于内存限制）写入数组，然后在子例程调用中提供该点。在尝试之前，我想我会看看是否有人对更好的方法有任何建议。尽可能减少内存占用量会很好。

Answer 1

从版本7和更高版本开始，GFortran具有并行的随机数生成器。在实现它时，这是我用来验证性能确实随着线程数量的增加而扩展的OpenMP代码（来自https://gcc.gnu.org/ml/gcc-patches/2015-12/msg02110.html）：


! Benchmark generating random numbers
! Janne Blomqvist 2015
program randbench
#ifdef _OPENMP
  use omp_lib
#endif
  implicit none
  integer, parameter :: dp=kind(0.d0)          ! double precision
  integer, parameter :: i64 = selected_int_kind(18) ! At least 64-bit integer

#ifdef _OPENMP
  print *, "Using up to ", omp_get_max_threads(), " threads."
#endif
  call genr4
  call genr8
contains
  subroutine genr4
    integer, parameter :: n = int(1e7)
    real, save :: r(n)
    integer :: i
    integer(i64) :: t1, t2, td
#ifdef _OPENMP
    integer :: blocks, blocksize, l, h
#endif
    Print *, "Generate default real random variables"
    call system_clock (t1)
    !$omp parallel do private(i)
    do i = 1, n
       call random_number(r(i))
    end do
    !$omp end parallel do
    call system_clock (t2)
    td = t2 - t1
    print *, "Generating ", n, " default reals individually took ", td, " ticks."
    call system_clock (t1)
#ifdef _OPENMP
    blocks = omp_get_max_threads()
    blocksize = n / blocks
    !$omp parallel do private(l,h,i)
    do i = 0, blocks - 1
       l = i * blocksize + 1
       h = l + blocksize - 1
       !print *, "Low: ", l, " High: ", h
       call random_number(r(l:h))
    end do
#else
    call random_number(r)
#endif
    Call system_clock (t2)
    print *, "Generating ", n, " default reals as an array took  ", t2-t1, &
         " ticks. => ind/arr = ", real(td, dp) / (t2-t1)
  end subroutine genr4

  subroutine genr8
    integer, parameter :: n = int(1e7)
    real(dp), save :: r(n)
    integer :: i
    integer(i64) :: t1, t2, td
#ifdef _OPENMP
    integer :: blocks, blocksize, l, h
#endif
    print *, "Generate double real random variables"
    call system_clock (t1)
    !$omp parallel do
    do i = 1, n
       call random_number(r(i))
    end do
    call system_clock (t2)
    td = t2 - t1
    print *, "Generating ", n, " double reals individually took  ", td, " ticks."
    call system_clock (t1)
#ifdef _OPENMP
    blocks = omp_get_max_threads()
    blocksize = n / blocks
    !$omp parallel do private(l,h,i)
    do i = 0, blocks - 1
       l = i * blocksize + 1
       h = l + blocksize - 1
       !print *, "Low: ", l, " High: ", h
       call random_number(r(l:h))
    end do
#else
    call random_number(r)
#endif
    call system_clock (t2)
    print *, "Generating ", n, " double reals as an array took   ", t2-t1, &
         " ticks. => ind/arr = ", real(td, dp) / (t2 -t1)
  end subroutine genr8

end program

有没有简单的方法可以在Fortran中使用随机数生成器进行并发计算？

1 个答案: