Question

如何找到列表中的所有最小元素？现在我有一个元组列表，即

[(10,'a'),(5,'b'),(1,'c'),(8,'d'),(1,'e')]

所以我希望输出是列表中所有最小元素的新列表。例如

 [(1,'c'),(1,'e')]

我尝试了

minimumBy (comparing fst) xs

但这只会返回第一个最小元素。

Answer 1

获得第一个值的最小值后，我们可以过滤这些项目上的列表。因为您要在此处检索最少项目列表，所以我们也可以通过返回一个空列表来覆盖空列表：

minimumsFst :: Ord a => [(a, b)] -> [(a, b)]
minimumsFst [] = []
minimumsFst xs = filter ((==) minfst . fst) xs
    where minfst = minimum (map fst xs)

例如：

Prelude> minimumsFst [(10,'a'),(5,'b'),(1,'c'),(8,'d'),(1,'e')]
[(1,'c'),(1,'e')]

Answer 2

Oneliner。关键是排序。

Prelude Data.List> let a = [(1,'c'),(2,'b'),(1,'w')]
Prelude Data.List> (\xs@((m,_):_) -> takeWhile ((== m) . fst ) xs) . sortOn fst $ a
[(1,'c'),(1,'w')]

Answer 3

这是一种可以一口气工作的解决方案（这里的大多数其他答案都是两遍：一个用于查找最小值，一个用于对其进行过滤），并且不依赖于如何实现排序功能以提高效率。

{-# LANGUAGE ScopedTypeVariables #-}

import Data.Foldable (foldl')

minimumsBy :: forall a. (a -> a -> Ordering) -> [a] -> [a]
minimumsBy _ [] = []
minimumsBy f (x:xs) = postprocess $ foldl' go (x, id) xs
  where
    go :: (a, [a] -> [a]) -> a -> (a, [a] -> [a])
    go acc@(x, xs) y = case f x y of
      LT -> acc
      EQ -> (x, xs . (y:))
      GT -> (y, id)
    postprocess :: (a, [a] -> [a]) -> [a]
    postprocess (x, xs) = x:xs []

请注意，我在这里使用的[a] -> [a]类型称为difference list，也称为Hughes list。

Answer 4

您也可以使用foldr轻松做到这一点：

minimumsFst :: Ord a => [(a, b)] -> [(a, b)]
minimumsFst xs = go (minfst xs) xs
  where
  go mn ls = foldr (\(x, y) rs -> if (x ==  mn) then (x,y) : rs else rs) [] xs
  minfst ls = minimum (map fst ls)

以您的示例为例：

   minimumsFst [(10,'a'),(5,'b'),(1,'c'),(8,'d'),(1,'e')]
=> [(1,'c'),(1,'e')]

Answer 5

您尝试过

minimumBy (comparing fst) xs

也可以写为

= head . sortBy (comparing fst) $ xs
= head . sortOn fst $ xs
= head . head . group . sortOn fst $ xs
= head . head . groupBy ((==) `on` fst) . sortOn fst $ xs

这仅返回第一个元素而不是它们的列表，因此只需删除多余的head即可获得所需的内容：

=        head . groupBy ((==) `on` fst) . sortOn fst $ xs

当然拥有head是不好的，因为它会在[]输入中出错。相反，我们可以使用安全选项

= concat . take 1 . groupBy ((==) `on` fst) . sortOn fst $ xs

通过任何方式调用minimum的解决方案对于空输入列表也不安全：

> head []
*** Exception: Prelude.head: empty list

> minimum []
*** Exception: Prelude.minimum: empty list

但是takeWhile是安全的：

> takeWhile undefined []
[]

编辑：由于懒惰，即使在最坏的情况下，最终版本的整体时间复杂度仍应为 O（n）。

如何在元组列表中找到所有最小元素？

5 个答案: