Question

在OPA中，很清楚如何针对condition AND condition进行查询：

values := {
  "value1": {
    "a": "one"
  },
  "value2": {
    "a": "one",
    "b": "two"
  },
  "value3": {
    "a": "one",
    "b": "one"
  }
}

goodValues = [name |
  value = values[name]
  value.a == "one"
  value.b == "one"
]

因此此处的goodValues仅包含value3。

但是如何查询condition OR condition，以使goodValues包含所有3个值，因为它们具有value.a == "one"或value.b == "one"？

Answer 1

将多个表达式连接在一起表示逻辑AND。要表达逻辑或，您可以定义多个具有相同名称的规则或函数。有几种不同的方法可以起作用。这在OPA的简介中介绍：https://www.openpolicyagent.org/docs/latest/#logical-or。

选项1：理解和功能

要针对该值表达的条件可以分解为辅助函数，然后理解查询可以引用该函数。

goodValues = [name |
  value := values[name]
  value_match(value)
]

value_match(v) {
  v.a == "one"
}

value_match(v) {
  v.b = "two"
}

选项2：增量规则

在OPA / Rego中，增量规则将一组值分配给变量。规则定义提供了生成设置值的逻辑。与理解不同，您可以重载规则定义（提供多个具有相同名称的规则）并像其他答案所解释的那样表达逻辑或。

# goodValues is a set that contains 'name' if...
goodValues[name] {
 value := values[name]  # name is in values
 value.a == "one"       # value.a is "one"
}

# goodvalues is a set that contains 'name' if...
goodValues[name] {
  value := values[name]  # name is in values
  value.b == "two"       # value.b is "two"
}

Answer 2

到目前为止，通过incremental set找到了一个丑陋的答案：

goodValues[name] {
  value = values[name]
  value.a == "one"
}

goodValues[name] {
  value = values[name]
  value.b == "one"
}

但是，如果这种普遍情况value = values[name]变得更加复杂怎么办？是否需要将其提取到一个单独的变量中（并在每个条件语句中对其进行迭代）？有更好的解决方案吗？

或在开放式政策代理（工会行为）中

2 个答案:

选项1：理解和功能

选项2：增量规则